Напишите пожалуйста мааленький скрипт... :)

Ascoron · Post by **Ascoron** » 2006-05-09 21:58:18

Der wrote: Ну дык используй тогда Изю и всё...

Этот макрос на Изю очень глюченый... Не всегда перекладывает кирку.

DerMeister =) · Post by **DerMeister =)** » 2006-05-09 22:02:09

Ascoron wrote:
Der wrote:
PS:Это конечно если у тя на шарде пишется название руды когда её выкапываешь
Да, пишется... Все руды на английском, а вот обычную руду на русском...

Ну хз... напиши в консоли ,showjournal и посмотри что там у тебя, а потом в скрипт впиши. И на самом деле я думаю что ничего страшного, если одна из галимых руд будет оставатся... ето всё же не 13 руд а одна) =) =) =)

Ascoron · Post by **Ascoron** » 2006-05-09 22:05:10

Der wrote:
Ascoron wrote:
Der wrote:
PS:Это конечно если у тя на шарде пишется название руды когда её выкапываешь
Да, пишется... Все руды на английском, а вот обычную руду на русском...
Ну хз... напиши в консоли ,showjournal и посмотри что там у тебя, а потом в скрипт впиши. И на самом деле я думаю что ничего страшного, если одна из галимых руд будет оставатся... ето всё же не 13 руд а одна) =) =) =)

Спасибо, сейчас проверю

)

DerMeister =) · Post by **DerMeister =)** » 2006-05-09 22:09:09

Только смотри, провера в журнале чувствительна к регистру! Rusty и rusty это РАЗНЫЕ вещи. Удачи

Ascoron · Post by **Ascoron** » 2006-05-09 22:16:08

Добавил в скрипт остальные руды...
Но оно чего-то не запускается

Code: Select all

... 
var pix='0x62C19316' 
... 
if uo.injournal("немного руды | Rusty | Old Copper | Dull Copper | Shadow | Merkite | Copper | Bronze | Silver | Rose | Agapite | Blood Rock |  Verite") then 
uo.deletejournal() 
uo.moveitem("pix", str(uo.getQuantity("pix")), uo.containerOf("pix"), str(uo.getX("pix")), str(uo.getY("pix")), str(uo.getZ("pix"))) 
...

Молвит "Line 1:parse error"

DerMeister =) · Post by **DerMeister =)** » 2006-05-09 22:19:30

Ну ты даёшь! Так и пиши что в скриптинге на инжекте ничего не понимаешь! Троеточие это я имел ввиду что это только кусочек скрипта... Тоесть ты должен сам этот код впихнуть в свой скрипт на копание...

Вощем кидай сюда весь скрипт и я тебе всё сделаю =)

Ascoron · Post by **Ascoron** » 2006-05-09 22:23:59

Code: Select all

;================================== 
;================================== 
; Script Name:   Mining Macro Creator 
; Author: MAXHO 
; Version: 0.6 Alpha 
; Client Tested with: 3.0.0c 
; EUO version tested with: 1.42 (build 008A) 
; Shard: only Age of Power 
; Revision Date: 2/07/2004 
; Public Release: -------- 
; Purpose: Macros for easy-creating mining script 
;================================== 
Set %ScriptVersion MMC_v_0.8 
CheckClientVersion: 
  If #CLIVER = 3.0.0c 
    Goto CheckEUOVer 
  Display ok Макрос работает только под 3.0.0с клиентом 
  Halt 
CheckEUOVer: 
If 1_42 in #EUOVER 
  Goto StartSetup 
  Display ok У вас старая изи уо. Скачайте новую на сайте www.easyuo.com $$ Или на www.online.com.ua/~kojsoft/easyuo.rar для укртраф. 
  Halt 
StartSetup: 
CALL Mining.cfg 1 
If %Config <> N/A 
  Goto InitMiningMacro 
CheckAllowExecute: 
  If EXEC in #OPTS 
    Goto ShowMenu 
  Display ok Вы не поставили в опциях Allow Execute. Без этой опции макрос не сохраниться. $$Зайдите в Tools > Options закладка Permissions снимите 2 верхние галочки и нажмите ОК. 
  Halt 
ShowMenu: 
;+++++++++++++++++++++++++++++++++++++++++ 
; Variable declaration 
;+++++++++++++++++++++++++++++++++++++++++ 
; output file name 
Set %MacroFileName Mining.cfg 
; current step 
Set %Stage 0 
; list of standart chests 
Set %Chests HKF_IIf_AUD_ZTD_CUD_BUD_UMF_TMF_WMF_VMF_HIf_KIf_JIf_IKF_KKF_SPF 
; list of standart bags 
Set %Bags CKF_LKF_IUD_KUD_ZJF 
; list of weapons 
Set %weapons SOH_ATF_KPH_EPH_CUH_CPH_YTH_RMH_NSF_ZRF_UOH_MPH_YSF_WTH_XRH_MTF_HSF_AUH_NMH_WRH_PPF_LSF_URH_RRH_BSF 
; standart backpack 
Set %backpacks ZJF 
Set %mainchest x 
Set %bag1 x 
Set %bag2 x 
Set %backpack x 
Set %weapon x 
; other variables 
Set %waypoint 0 
Set %pointnum 1 
Set %place 0 
;+++++++++++++++++++++++++++++++++++++++++ 
; Initialize 
;+++++++++++++++++++++++++++++++++++++++++ 
; show start window 
GoSub ShowBaseWindow 
GoSub ShowStage0 

;+++++++++++++++++++++++++++++++++++++++++ 
; Button press wait 
;+++++++++++++++++++++++++++++++++++++++++ 
WaitForButtonPress: 
  If #Menubutton = CLOSED || #Menubutton = Exit 
  { 
    Menu hide 
    Halt 
  } 
  If #Menubutton = NEXT 
  { 
    Set #Menubutton N/A 
    Goto CheckNextStage 
  } 
  If #Menubutton = But1 
  { 

    Set #Menubutton N/A 
    GoSub TargetItem %Chests СУНДУК 1 
    GoSub ShowStage2 
  } 
  If #Menubutton = But2 
  { 
    Set #Menubutton N/A 
    GoSub TargetItem %Bags СУМКА 2 
    GoSub ShowStage2 
  } 
  If #Menubutton = But3 
  { 
    Set #Menubutton N/A 
    GoSub TargetItem %Bags СУМКА 3 
    GoSub ShowStage2 
  } 
  If #Menubutton = But4 
  { 
    Set #Menubutton N/A 
    GoSub TargetItem %weapons ОРУЖИЕ 4 
    GoSub ShowStage2 
  } 
  If #Menubutton = But5 
  { 
    Set #Menubutton N/A 
    GoSub TargetItem %backpacks БЕКПАК 5 
    GoSub ShowStage2 
  } 
  If #Menubutton = Record 
  { 
    Set #Menubutton N/A 
    Set %x %pointnum + 2 
    If %stage = 4 
      GoSub StartMarkWaypoins %x 
    If %stage = 3 
      GoSub StartMarkWaypoins %pointnum 
  } 
   If #Menubutton = MARK 
  { 
    Set #Menubutton N/A 
    GoSub MarkPlace 
  } 
Goto WaitForButtonPress 

;+++++++++++++++++++++++++++++++++++++++++ 
; Check next stage, If all ok Goto next stage 
;+++++++++++++++++++++++++++++++++++++++++  

CheckNextStage: 
  If %stage = 1 
    Goto CheckStage1 
  If %stage = 2 
    Goto CheckStage2 
  If %stage = 3 || %stage = 4 
    Goto CheckStage34 
  If %stage = 5 
    Goto CheckStage5 
  If %stage = 6 
    Goto CheckStage6 
  label1: 
  GoSub NextStage %stage 
  Set %stage %stage + 1 
  Goto WaitForButtonPress 

Sub NextStage 
  Menu hide 
  GoSub ShowBaseWindow 
  If %1 = 0 
    GoSub ShowStage1 
  If %1 = 1 
    GoSub ShowStage2 
  If %1 = 2 
    GoSub ShowStage3 
  If %1 = 3 
    GoSub ShowStage4 
  If %1 = 4 
    GoSub ShowStage5 
  If %1 = 5 
    GoSub ShowStage6 
Return 

;+++++++++++++++++++++++++++++++++++++++++ 
; Main interface 
;+++++++++++++++++++++++++++++++++++++++++ 

; show main clear window 
Sub ShowBaseWindow 
  Menu HideEUO 
  set !winwidth 495 
  set !winheigth 360 
  set !winposx 520 
  set !winposy 320 
  Menu clear 
  Menu Window Color $FFFFFF 
  Menu Window Size !winwidth !winheigth 
  GoSub SetDefaultFont 
  Menu Shape EUOShape1 0 0 165 317 3 7 1 Black 7 $005B0000 
  Menu Shape EUOShape2 0 316 500 44 3 7 1 BtnFace 7 BtnFace 
  Menu shape splitline1 0 317 500 1 3 7 7 $F0FBff 
  Menu shape splitline1 0 316 500 1 3 7 7 $99a8ac 
  Menu Button Exit 412 328 75 25 Отмена 
  If %Stage < 6 
    Menu Button Next 328 328 75 25 Дальше > 
  else 
    Menu Button Next 328 328 75 25 Финишь 
  If %Stage > 0 
    Menu Button Back 244 328 75 25 < Назад 
  Set #Menubutton x 
  Menu font color $CC5511 
  Menu font size 9 
  Menu font name Verdana 
  Menu font style b 
  Menu Text EUOLabel3 5 5 Setup wizzard v0.7a 
  Menu Text EUOLabel3 5 25 Crafted by MAXHO 
  Menu font color white 
  Menu Text EUOLabel3 4 3 Setup wizzard v0.7a 
  Menu Text EUOLabel3 4 23 Crafted by MAXHO 
  Menu show !winposx !winposy 
Return 

; change font 
Sub SetDefaultFont 
  Menu font size 8 
  Menu font style a 
  Menu Font Transparent #true 
  Menu font name MS Sans SerIf 
  Menu Font Color $000000 
  Return 

Sub SetTitleFont 
  Menu font size 16 
  Menu font style b 
  Menu Font Transparent #true 
  Menu font name MS Sans SerIf 
  Menu Font Color $000000 
  Return 

Sub ShowSymbol 
  Menu font name wingdings 
  Menu font size 150 
  Menu font style b 
  Menu Font Color %1 
  Menu text symbol 4 50 %3 
  Menu Font Color %2 
  Menu text symbol 0 46 %3 
  GoSub SetDefaultFont 
  Return 

; show stage windows 1-7 

; show start window 
Sub ShowStage0 
  Menu Window Title Mining Macro Creator - Установка 
  GoSub SetTitleFont 
  Menu Text TitleText 179 12 Добро пожаловать в мастер 
  Menu Text TitleText 179 34 настройки макроса на майнинг. 
  GoSub SetDefaultFont 
  Menu Text EUOLabel3 179 108 Эта программа установит и настроит макрос на майнинг. 
  Menu Text EUOLabel4 179 126 Функции макроса: 
  Menu Text EUOLabel4 179 146 - легко и быстро настраиваеться под любую шахту 
  Menu Text EUOLabel4 179 166 - может обкапывать столько точек сколько укажете 
  Menu Text EUOLabel4 179 186 - идет воскрешаться если чара убьют 
  Menu Text EUOLabel4 179 206 - сам берет кирки и одеваеться 
  Menu Text EUOLabel4 179 226 - относит руду в дом, берет кирки если сломаються 
  Menu Text EUOLabel4 179 246 - убивает и лутит и секлктон магов 
  Menu Text EUOLabel4 179 266 - лечиться и ест фишстейки 
  GoSub ShowSymbol $CC5511 $FFFFFF T 
  Return 

; show stage 1 window 
Sub ShowStage1 
  Menu Window Title Mining Macro Creator - Этап 1 
  GoSub SetTitleFont 
  Menu Text TitleText 179 12 Этап №1 
  Menu Text TitleText 179 34 Необходимые предметы 
  GoSub SetDefaultFont 
  Menu Text EUOLabel3 179 108 Прежде чем начать настройку макроса вам необходимо: 
  Menu Text EUOLabel4 179 136 - настроеный Yoko Injection 
  Menu Text EUOLabel4 179 156 - дом или фонарь с залоченым снаружи сундуком 
  Menu Text EUOLabel4 179 176 - две сумки, одна для армора и одна для кирок 
  Menu Text EUOLabel4 179 196 - бинты и фишстейки 
  Menu Text EUOLabel1 184 232 Выберите в чем будете копать: 
  Menu Check EUOCheckBox1 184 248 97 17 #false Шлем 
  Menu Check EUOCheckBox2 184 264 97 17 #false Горжетка 
  Menu Check EUOCheckBox3 184 280 97 17 #false Перчатки 
  Menu Check EUOCheckBox4 184 296 97 17 #false Налокотники 
  Menu Check EUOCheckBox5 284 248 97 17 #false Хитер 
  Menu Check EUOCheckBox6 284 296 97 17 #false Нагрудник 
  Menu Check EUOCheckBox7 284 264 97 17 #false Штаны 
  Menu Check EUOCheckBox8 284 280 97 17 #false Подштанники 
  Menu Check EUOCheckBox9 384 248 97 17 #false Чеин туника 
  Menu Check EUOCheckBox10 384 296 97 17 #false Чеин шлем 
  Menu Check EUOCheckBox11 384 264 97 17 #false Ринг рукава 
  Menu Check EUOCheckBox12 384 280 97 17 #false Кайт хитер 
  GoSub ShowSymbol $CC5511 $FFFFFF T 
Return 

; show stage 2 window 
Sub ShowStage2 
  Menu Window Title Mining Macro Creator - Этап 2 
  GoSub SetTitleFont 
  Menu Text TitleText 179 12 Этап №2 
  Menu Text TitleText 179 34 Определение ID сундука 
  GoSub SetDefaultFont 
  Menu Text EUOLabel3 179 108 1) Подойдите вплотную к сундуку залоченому у дома. 
  Menu Text EUOLabel4 179 136 2) Выберите сундук для инготов --> 
  Menu Text EUOLabel4 179 166 3) Выберите сумку с кирками  ------> 
  Menu Text EUOLabel4 179 196 4) Выберите сумку с армором  -----> 
  Menu Text EUOLabel4 179 226 5) Выберите выберите оружие  -----> 
  Menu Text EUOLabel4 179 256 6) Выберите выберите бекпак  -----> 
  Menu Text EUOLabel4 426 136 ID: %MainChest 
  Menu Text EUOLabel4 426 166 ID: %Bag1 
  Menu Text EUOLabel4 426 196 ID: %Bag2 
  Menu Text EUOLabel4 426 226 TYPE: %weapon 
  Menu Text EUOLabel4 426 256 ID: %backpack 
  Menu Button But1 360 133 63 19 Выбрать 
  Menu Button But2 360 163 63 19 Выбрать 
  Menu Button But3 360 193 63 19 Выбрать 
  Menu Button But4 360 223 63 19 Выбрать 
  Menu Button But5 360 253 63 19 Выбрать 
  GoSub ShowSymbol $CC5511 $FFFFFF T 
Return 

; show stage 3 window 
Sub ShowStage3 
  Menu Window Title Mining Macro Creator - Этап 3 
  GoSub SetTitleFont 
  Menu Text TitleText 179 12 Этап №3 
  Menu Text TitleText 179 34 Вейпоинты Шахта - Дом 
  GoSub SetDefaultFont 
  Menu Text EUOLabel3 179 108 Теперь займемся разметкой вейпоинтов. 
  Menu Text EUOLabel4 179 126 Вейпоинты - точки по которым будет бегать ваш чар. 
  Menu Text EUOLabel4 179 156 1) Станьте вплотную возле сундука 
  Menu Text EUOLabel4 179 176 2) Нажмите "Запись" и идите в шахту. 
  Menu Text EUOLabel4 179 196 3) Когда будете в шахте нажмите "Стоп". 
  Menu Text EUOLabel4 179 216 4) Когда сохраняться вейпоинты жмите "Запись" 
  Menu Text EUOLabel4 179 236 5) Идите назад к сундуку, возле сундука жмите "Стоп". 
  Menu Button Stop 412 268 75 25 Стоп 
  Menu Button Record 328 268 75 25 Запись 
  GoSub ShowSymbol $CC5511 $FFFFFF T 
  Return 

; show stage 4 window 
Sub ShowStage4 
  Menu Window Title Mining Macro Creator - Этап 4 
  GoSub SetTitleFont 
  Menu Text TitleText 179 12 Этап №4 
  Menu Text TitleText 179 34 Вейпоинты Шахта - Крест 
  GoSub SetDefaultFont 
  Menu Text EUOLabel3 179 108 Если вас убьют во время макроса, чар сам побежит к кресту. 
  Menu Text EUOLabel4 179 126 Их можно не определять. Чар просто будет ждать пока его 
  Menu Text EUOLabel4 179 136 воскресят. После чего побежит одеваться и дальше копать. 
  Menu Text EUOLabel4 179 156 1) Станьте вплотную возле сундука 
  Menu Text EUOLabel4 179 176 2) Нажмите "Запись" и идите к кресту (хилеру). 
  Menu Text EUOLabel4 179 196 3) Когда будете у креста нажмите "Стоп". 
  Menu Text EUOLabel4 179 216 4) Когда сохраняться вейпоинты  жмите "Запись" 
  Menu Text EUOLabel4 179 236 5) Идите назад к сундуку, возле сундука жмите "Стоп". 
  Menu Button Stop 412 268 75 25 Стоп 
  Menu Button Record 328 268 75 25 Запись 
  GoSub ShowSymbol $CC5511 $FFFFFF T 
  Return 

; show stage 5 window 
Sub ShowStage5 
  Menu Window Title Mining Macro Creator - Этап 5 
  GoSub SetTitleFont 
  Menu Text TitleText 179 12 Этап №5 
  Menu Text TitleText 179 34 Разметка шахты 
  GoSub SetDefaultFont 
  Menu Text EUOLabel3 179 108 Предпоследний этап - маркировка точек копания. 
  Menu Text EUOLabel4 179 126 Для нормальной работы разметь как минимум 5 точек. 
  Menu Text EUOLabel4 179 146 Чар обкапывает на каждой точке 9 клеток. 
  Menu Text EUOLabel4 179 166 1) Выберите место обкопки и нажми "Пометить" 
  Menu Text EUOLabel4 179 186 2) Пометь как минимум 5 точек. 
  Menu Text EUOLabel4 179 206 3) Когда пометишь все точки жми "Дальше" 
  Menu Button Mark 412 268 75 25 Пометить 
  GoSub ShowSymbol $CC5511 $FFFFFF T 
  Return 

; show stage 6 window 
Sub ShowStage6 
  Menu Window Title Mining Macro Creator - Этап 6 
  GoSub SetTitleFont 
  Menu Text TitleText 179 12 Этап №6 
  Menu Text TitleText 179 34 Запись скрипта 
  GoSub SetDefaultFont 
  Menu Text EUOLabel3 179 108 Итак осталось сохранить макрос. 
  Menu text intro 179 155 Выберите свою операционную систему: 
  Menu Combo create OperatingSystem 179 175 280 
  Menu Combo add OperatingSystem Windows NT, 2000, XP and higher 
  Menu Combo add OperatingSystem Windows 95, 98 or ME 
  GoSub ShowSymbol $CC5511 $FFFFFF T 
  Return 

;+++++++++++++++++++++++++++++++++++++++++ 
; Stage 1 Subs 
;+++++++++++++++++++++++++++++++++++++++++ 

CheckStage1: 
  Menu Get EUOCheckBox1 
  If #Menures = -1 
    Set %Helmet OSH 
  Menu Get EUOCheckBox2 
  If #Menures = -1 
    Set %Gorget NSH 
  Menu Get EUOCheckBox3 
  If #Menures = -1 
    Set %Gloves ISH 
  Menu Get EUOCheckBox4 
  If #Menures = -1 
    Set %Arms MSH 
  Menu Get EUOCheckBox5 
  If #Menures = -1 
    Set %Shield CIK 
  Menu Get EUOCheckBox6 
  If #Menures = -1 
    Set %Body KSH 
  Menu Get EUOCheckBox7 
  If #Menures = -1 
    Set %Leggins WSH 
  Menu Get EUOCheckBox8 
  If #Menures = -1 
    Set %Pants NKH 
;===================== 
  Menu Get EUOCheckBox9 
  If #Menures = -1 
    Set %Tunic IKH 
  Menu Get EUOCheckBox10 
  If #Menures = -1 
    Set %Helmet1 DPH 
  Menu Get EUOCheckBox11 
  If #Menures = -1 
    Set %Arms1 XLH 
  Menu Get EUOCheckBox12 
  If #Menures = -1 
    Set %Shield1 AIK 
  Goto Label1 

;+++++++++++++++++++++++++++++++++++++++++ 
; Stage 2 Subs 
;+++++++++++++++++++++++++++++++++++++++++ 
CheckStage2: 
  If %MainSunduk = X || %Bag1 = X || %Bag2 = X || %weapon = X || %backpack = X 
  { 
    Display ok Вы не все выбрали. 
    Goto WaitForButtonPress 
  } 
Goto Label1 

Sub TargetItem 
  Menu hide 
  Set #TARGCURS 1 
  WaitForTarget: 
    If #TARGCURS = 0 
      Goto Done 
  Goto WaitForTarget 
  Done: 
  FindItem #LTARGETID 
  If #FINDTYPE in %1 
  { 
    Set %ItemID #FINDID 
    Set %ItemTYPE #FINDTYPE 
  } 
  else 
  { 
    Display ok ЭТО НЕ %2 
    Set %ItemID X 
    Set %ITEMTYPE X 
  } 
  If %3 = 1 
    Set %MainChest %ItemID 
  If %3 = 2 
    Set %Bag1 %ItemID 
  If %3 = 3 
    Set %Bag2 %ItemID 
  If %3 = 4 
    Set %weapon %ItemTYPE 
  If %3 = 5 
    Set %backpack %ItemID 
  Set #Menubutton N/A 
  If %MainSunduk <> X && %Bag1 <> X && %Bag2 <> X && %weapon <> X && %backpack <> X 
    Display ok Все определено. Жмите далее. 
  GoSub ShowBaseWindow 
Return 

;+++++++++++++++++++++++++++++++++++++++++ 
; Stage 3-4 Subs 
;+++++++++++++++++++++++++++++++++++++++++ 
CheckStage34: 
  If %waypoint <> 1 
  { 
    Display ok Вы не разметили все вейпоинты 
    Goto WaitForButtonPress 
  } 
  Set %waypoint 0 
Goto Label1 

Sub StartMarkWaypoins 
  Set %point 1 
  Set %spotX . %point #CHARPOSX 
  Set %spotY . %point #CHARPOSY 
  Set %chardir #CHARDIR 
  If %1 = 1 
  { 
    Display ok Идите в шахту. Внимание! Точка сохраняеться каждый раз когда вы изменяете направление $$ Совет: старайтесь выбрать путь как можно прямее и с наименьшим числом поворотов. 
    Event SysMessage Go dirrectly to the mine 
  } 
  If %1 = 2 
  { 
    Display ok Идите назад к сундуку 
    Event SysMessage Go dirrectly to the chest for iron ore 
  } 
  If %1 = 3 
  { 
    Display ok Идите к хилеру или кресту, старайтесь выбрать путь, чтоб не натыкаться на респ монстров, иначе будете долго бегать :) 
    Event SysMessage Go dirrectly to the healer or ankh 
  } 
  If %1 = 4 
  { 
    Display ok Идите назад к сундуку 
    Event SysMessage Go back to the chest wirth iron ore 
  } 
WriteSpot: 
  If %chardir <> #CHARDIR 
  { 
    Set %point %point + 1 
    Set %chardir #CHARDIR 
    Set %spotX . %point #CHARPOSX 
    Set %spotY . %point #CHARPOSY 
    Event SysMessage Point saved. 
  } 
  If #Menubutton = Stop 
  { 
    Set %point %point + 1 
    Set %chardir #CHARDIR 
    Set %spotX . %point #CHARPOSX 
    Set %spotY . %point #CHARPOSY 
    Event SysMessage %point waypoints saved. 
    Goto SaveWayPoins 
  } 
Goto WriteSpot 
SaveWayPoins: 
  Set %rail . %1 %point 
  for %j 1 %point 
  { 
    If %1 = 1 
    { 
      Set %WayPoint1X . %j %spotX . %j 
      Set %WayPoint1y . %j %spoty . %j 
    } 
    If %1 = 2 
    { 
      Set %WayPoint2X . %j %spotX . %j 
      Set %WayPoint2y . %j %spoty . %j 
    } 
    If %1 = 3 
    { 
      Set %WayPoint3X . %j %spotX . %j 
      Set %WayPoint3y . %j %spoty . %j 
    } 

    If %1 = 4 
    { 
      Set %WayPoint4X . %j %spotX . %j 
      Set %WayPoint4y . %j %spoty . %j 
    } 
  } 
  Display ok Вейпоинты сохранены 
  Set %pointnum %pointnum + 1 
  If %pointnum > 2 
  { 
    Set %pointnum 1 
    Set %waypoint 1 
    Display ok Вейпоинты определены, жмите "Дальше". 

  } 
  Return 

;+++++++++++++++++++++++++++++++++++++++++ 
; Stage 5 Subs 
;+++++++++++++++++++++++++++++++++++++++++ 
CheckStage5: 
  If %place < 5 
  { 
    Display ok Отметь хотябы 5 точек 
    Goto WaitForButtonPress 
  } 
Goto Label1 

Sub MarkPlace 
  Set %place %place + 1 
  Set %minex . %place #CHARPOSX 
  Set %mineY . %place #CHARPOSY 
  Menu Hide 
  Display ok Место помечено 
  GoSub ShowBaseWindow 
  GoSub ShowStage5 
  Menu Text EUOLabel4 179 236 Помечено %place мест 
  Return 

;+++++++++++++++++++++++++++++++++++++++++ 
; Stage 6 Subs 
;+++++++++++++++++++++++++++++++++++++++++ 
CheckStage6: 
    Menu get OperatingSystem 
    If #Menures > 0 

      Goto SaveTheScript 
    Display ok Выберите вашу операционную систему! 
    Goto WaitForButtonPress 

SaveTheScript: 
  If #Menures = 1 
    Set %cmd cmd.exe 
  If #Menures = 2 
    Set %cmd command.com 
  Menu text intro1 179 220 Откинтесь на спинку кресла и подождите 
  Menu text intro1 179 240 пока сохраниться скрипт. 
  Display ok Подождите пока создаеться скрипт. Это может занять несколько минут. 
  Menu text intro1 179 260 Статус: Сохраняю переменные... 
  execute %cmd /c echo If % , 1 = 1 > %MacroFileName 
  execute %cmd /c echo { >> %MacroFileName 
  execute %cmd /c echo Set % , Config 1 >> %MacroFileName 
  execute %cmd /c echo Set % , weapon %weapon >> %MacroFileName 
  execute %cmd /c echo Set % , MainChest %MainChest >> %MacroFileName 
  execute %cmd /c echo Set % , Bag1 %Bag1 >> %MacroFileName 
  execute %cmd /c echo Set % , Bag2 %Bag2 >> %MacroFileName 
  execute %cmd /c echo Set % , backpack %backpack >> %MacroFileName 
  execute %cmd /c echo Set % , Helmet %Helmet >> %MacroFileName 
  execute %cmd /c echo Set % , Gorget %Gorget >> %MacroFileName 
  execute %cmd /c echo Set % , Gloves %Gloves >> %MacroFileName 
  execute %cmd /c echo Set % , Arms %Arms >> %MacroFileName 
  execute %cmd /c echo Set % , Shield %Shield >> %MacroFileName 
  execute %cmd /c echo Set % , Body %Body >> %MacroFileName 
  execute %cmd /c echo Set % , Leggins %Leggins >> %MacroFileName 
  execute %cmd /c echo Set % , Pants %Pants >> %MacroFileName 
  execute %cmd /c echo Set % , Shield1 %Shield1 >> %MacroFileName 
  execute %cmd /c echo Set % , Arms1 %Arms1 >> %MacroFileName 
  execute %cmd /c echo Set % , Tunic %Tunic >> %MacroFileName 
  execute %cmd /c echo Set % , Helmet1 %Helmet1 >> %MacroFileName 
  execute %cmd /c echo } >> %MacroFileName 
  GoSub ShowBaseWindow 
  GoSub ShowStage6 
  Menu text intro1 179 220 Откинтесь на спинку кресла и подождите 
  Menu text intro1 179 240 пока сохраниться скрипт. 

  Menu text intro1 179 260 Статус: Сохраняю список процедур... 
  execute %cmd /c echo If % , 1 = 2 >> %MacroFileName 
  execute %cmd /c echo GoSub MoveToDigPosition >> %MacroFileName 
  execute %cmd /c echo If % , 1 = 3 >> %MacroFileName 
  execute %cmd /c echo GoSub MoveToTheMine >> %MacroFileName 
  execute %cmd /c echo If % , 1 = 4 >> %MacroFileName 
  execute %cmd /c echo GoSub MoveToTheHouseA >> %MacroFileName 
  execute %cmd /c echo If % , 1 = 5 >> %MacroFileName 
  execute %cmd /c echo GoSub MoveToTheHouseB >> %MacroFileName 
  execute %cmd /c echo If % , 1 = 6 >> %MacroFileName 
  execute %cmd /c echo GoSub MoveToTheAnkh >> %MacroFileName 
  execute %cmd /c echo EXIT >> %MacroFileName 
  GoSub ShowBaseWindow 
  GoSub ShowStage6 
  Menu text intro1 179 220 Откинтесь на спинку кресла и подождите 
  Menu text intro1 179 240 пока сохраниться скрипт. 
  Menu text intro1 179 260 Статус: Сохраняю вейпоинты к шахте... 
  execute %cmd /c echo Sub MoveToTheMine >> %MacroFileName 
  for %j 1 %rail1 
  { 
    Set %X1 %WayPoint1X . %j 
    Set %Y1 %WayPoint1Y . %j 
    execute %cmd /c echo move %X1 %Y1 0 >> %MacroFileName 
  } 
  execute %cmd /c echo RETURN >> %MacroFileName 
  GoSub ShowBaseWindow 
  GoSub ShowStage6 
  Menu text intro1 179 220 Откинтесь на спинку кресла и подождите 
  Menu text intro1 179 240 пока сохраниться скрипт. 
  Menu text intro1 179 260 Статус: Сохраняю вейпоинты шахта-дом 
  execute %cmd /c echo Sub MoveToTheHOUSEA >> %MacroFileName 
  for %j 1 %rail2 
  { 
    Set %X1 %WayPoint2X . %j 
    Set %Y1 %WayPoint2Y . %j 
    execute %cmd /c echo move %X1 %Y1 0 >> %MacroFileName 
  } 
  execute %cmd /c echo RETURN >> %MacroFileName 
  GoSub ShowBaseWindow 
  GoSub ShowStage6 
  Menu text intro1 179 220 Откинтесь на спинку кресла и подождите 
  Menu text intro1 179 240 пока сохраниться скрипт. 
  Menu text intro1 179 260 Статус: Сохраняю вейпоинты дом - крест 
  execute %cmd /c echo Sub MoveToTheHOUSEB >> %MacroFileName 
  for %j 1 %rail4 
  { 
    Set %X1 %WayPoint4X . %j 
    Set %Y1 %WayPoint4Y . %j 
    execute %cmd /c echo move %X1 %Y1 0 >> %MacroFileName 
  } 
  execute %cmd /c echo RETURN >> %MacroFileName 
  GoSub ShowBaseWindow 
  GoSub ShowStage6 
  Menu text intro1 179 220 Откинтесь на спинку кресла и подождите 
  Menu text intro1 179 240 пока сохраниться скрипт. 
  Menu text intro1 179 260 Статус: Сохраняю вейпоинты крест - дом 
  execute %cmd /c echo Sub MoveToTheAnkh >> %MacroFileName 
  for %j 1 %rail3 
  { 
    Set %X1 %WayPoint3X . %j 
    Set %Y1 %WayPoint3Y . %j 
    execute %cmd /c echo move %X1 %Y1 0 >> %MacroFileName 
  } 
  execute %cmd /c echo RETURN >> %MacroFileName 
  GoSub ShowBaseWindow 
  GoSub ShowStage6 
  Menu text intro1 179 220 Откинтесь на спинку кресла и подождите 
  Menu text intro1 179 240 пока сохраниться скрипт. 
  Menu text intro1 179 260 Статус: Сохраняю точки обкопки... 
  execute %cmd /c echo Sub MoveToDigPosition >> %MacroFileName 
  execute %cmd /c echo Set * , place * , place + 1 >> %MacroFileName 
  set %p %place + 1 
  execute %cmd /c echo If * , place = %p >> %MacroFileName 
  execute %cmd /c echo Set * , place 1 >> %MacroFileName 
  for %j 1 %place 
  { 
  execute %cmd /c echo If * , place = %j >> %MacroFileName 
  execute %cmd /c echo { >> %MacroFileName 
  Set %x2 %minex . %j 
  Set %y2 %miney . %j 
  execute %cmd /c echo Set * , x %x2  >> %MacroFileName 
  execute %cmd /c echo Set * , y %y2  >> %MacroFileName 
  execute %cmd /c echo } >> %MacroFileName 
  } 
  execute %cmd /c echo Move * , x * , y 0 >> %MacroFileName 
  execute %cmd /c echo Wait 3s >> %MacroFileName 
  execute %cmd /c echo RETURN >> %MacroFileName 
  Wait 2s 
  GoSub ShowBaseWindow 
  GoSub ShowStage6 
  Menu text intro1 179 220 Откинтесь на спинку кресла и подождите 
  Menu text intro1 179 240 пока сохраниться скрипт. 
  Menu text intro1 179 260 Статус: Макрос сохранен 
  Display ok Макрос сохренен можно приступать к копанию! :) Перезапустите скрипт. 
  Menu hide 
  Halt 

;=========================================== 
; part 2 
; Script name: Macros for mining v 5.0 
; Author: MAXHO 
; Client Tested with: 3.0.0c 
; EUO version tested with: 1.42 (build 008A) 
; Shard: only Age of Power 
; Revision Date: 3/07/2004 
;=========================================== 
InitMiningMacro: 
; calculating max weight & maxhits 
  If #INT >= #STR && #INT >= #DEX 
  { 
    Set %var1 #STR + #INT 
    Set %MaxHits %var1 / 2 
  } 
  If #DEX >= #STR && #DEX >= #INT 
  { 
    Set %var1 #STR + #DEX 
    Set %MaxHits %var1 / 2 
  } 
  Set %MaxWeight #STR * 3 - 40 
; inititlize 
  Set *place 0 
  Set %square 1 
  Set %position s 
  Set #SYSMsgCOL 88 
  Event SysMessage Mining macro v5.0 by MAXHO 
  Event SysMessage Starting macro... 
  GoSub Autorun_on 
  Msg 'pc repeat on $ 
  Msg ,useobject %backpack $ 
  Wait 3s 
  Set #CONTPOSX 758 
  Set #CONTPOSY 358 
  CALL Mining.cfg 2 
Begin: 
  Msg 'pc mine %position $ 
  Wait 1s 
WaitWhileDigging: 
  If #HITS = 0 
    GoSub GoingToHealer 
  If #WEIGHT > %MAXWEIGHT 
    GoSub StoreOre 
  GoSub Findlich 
  GoSub CheckPikeAxe 
  GoSub Scan 
  GoSub ScanMessages 3 
  GoSub SaySomeSheet 
  Wait 1s 
  Goto WaitWhileDigging 

Sub Scan 
  If #SYSMsg = N/A || #SYSMsg = 201 
  { 
    Wait 2s 
    If #SYSMsg = N/A || #SYSMsg = 201 
    { 
      GoSub Next 
      Msg 'pc mine %position $ 
    } 
    Return 
  } 
  If #SYSMsg = >4 ; ТУТ ИЗМЕНИТЬ! 
  { 
    GoSub StopMine 
    Wait 3s 
    Msg 'pc mine %position $ 
    Return 
  } 
  Return 

Sub ScanMessages 
  For %h 1 %1 
  { 
    ScanJournal %h 
    If WHAT_MACROS in #JOURNAL 
    { 
      Msg I am using MAXHOs macros for mining %ScriptVersion $ 
      DeleteJournal %h 
    } 
  } 
  Return 
Sub StopMine 
  Msg 'pc repeat off $ 
  Wait 1s 
  Msg 'pc repeat on $ 
  Return 

Sub CheckHeal 
  If #HITS >= %MAXHITS 
    Return 
  Heal: 
    FindItem ZLF 
    If #FINDKIND = -1 
      Return 
    Msg 'pc heal self $ 
    Wait 9s 
    If #HITS < %MAXHITS 
      Goto Heal 
Return 

Sub Loot 
Wait 2s 
FindLoot: 
  FindItem POF_BFF_GFF 
  If #FINDKIND = -1 
    Return 
  If #FINDDIST > 3 
  { 
    IgnoreItem #FINDID 
    Goto FindLoot 
  } 
  Msg ,moveitem #FINDID 5000 %backpack $ 
  Wait 1s 
  IgnoreItem #FINDID 
  Goto FindLoot 
Lich: 
  Finditem WD_WE 
  If #FINDKIND = -1 
  { 
    wait 2s 
    Msg ,useobject lastcorpse $ 
    GoSub Loot 
    Wait 2s 
    GoSub CheckHeal 
    Move *x *y 0 
    Wait 3s 
    Goto Begin 
  } 
  Event Macro 27 
  Wait 1s 
  Move #FINDX #FINDY 0 1s 
Goto Lich 

Sub Findlich 
  Finditem WD_WE 
  If #FINDKIND <> -1 
  { 
    Set #LTARGETID #FINDID 
    Event SysMessage WARNING!!! You just dig out a bone mage or Lich! 
    Goto Lich 

  } 
Return 

Sub GoingToHealer 
  Call Mining.cfg 4 
  Call Mining.cfg 6 
; wait for resurrect 
  Res: 
    FindItem ILL_XHL_PKL_QKL 
    Msg ,useobject #FINDID $ 
    Wait 4s 
    If #HITS = 0 
  Goto Res 
  Msg ,useobject %backpack $ 
  Wait 2s 
  Set #CONTPOSX 758 
  Set #CONTPOSY 358 
  Call Mining.cfg 5 
  GoSub Equip 
  GoSub CheckHeal 
  Call Mining.cfg 3 
  Move *x *y 0 
Return 

Sub CheckBandages 
  FindItem ZLF 
  If #FINDKIND = -1 
  { 
    Event SysMessage Y MEH9l HETY 6OJlbWE 6uHTOB 
    Move *x *y 0 
    Goto Begin 
  } 
Return 

Sub Equip 
  Set %time 6 
  Msg ,setreceivingcontainer %backpack $ 
  Msg ,findtype %weapon -1 %Bag2 $ 

  Msg ,equip Rhand finditem $ 
  If %Gloves <> N/A 
  { 
    Msg ,findtype 0x1414 -1 %Bag2 $ 
    Msg ,equip Gloves finditem $ 
    Set %time %time + 2 
  } 
  If %Helmet <> N/A 
  { 
    Msg ,findtype 0x1412 -1 %Bag2 $ 
    Msg ,equip Hat finditem $ 
    Set %time %time + 2 
  } 
  If %Gorget <> N/A 
  { 
    Msg ,findtype 0x1413 -1 %Bag2 $ 
    Msg ,equip Neck finditem $ 
    Set %time %time + 2 
  } 
  If %Pants <> N/A 
  { 
    Msg ,findtype 0x13c3 -1 %Bag2 $ 
    Msg ,equip Pants finditem $ 
    Set %time %time + 2 
  } 
  If %Body <> N/A 
  { 
    Msg ,findtype 0x1416 -1 %Bag2 $ 
    Msg ,equip Torso finditem $ 
    Set %time %time + 2 
  } 
  If %Leggins <> N/A 
  { 
    Msg ,findtype 0x141a -1 %Bag2 $ 
    Msg ,equip Legs finditem $ 
    Set %time %time + 2 
  } 
  If %Shield <> N/A 
  { 
    Msg ,findtype 0x1b76 -1 %Bag2 $ 
    Msg ,equip Lhand finditem $ 
    Set %time %time + 2 
  } 
  If %Arms <> N/A 
  { 
    Msg ,findtype 0x1410 -1 %Bag2 $ 
    Msg ,equip Arms finditem $ 
    Set %time %time + 2 
  } 
;===== 
  If %Arms1 <> N/A 
  { 
    Msg ,findtype 0x13EF -1 %Bag2 $ 
    Msg ,equip Arms finditem $ 
    Set %time %time + 2 
  } 
  If %Tunic <> N/A 
  { 
    Msg ,findtype 0x13C4 -1 %Bag2 $ 
    Msg ,equip Torso finditem $ 
    Set %time %time + 2 
  } 
  If %Shield1 <> N/A 
  { 
    Msg ,findtype 0x1B74 -1 %Bag2 $ 
    Msg ,equip Lhand finditem $ 
    Set %time %time + 2 
  } 
  If %Helmet1 <> N/A 
  { 
    Msg ,findtype 0x13BB -1 %Bag2 $ 
    Msg ,equip Hat finditem $ 
    Set %time %time + 2 
  } 
; take pike axe 
  Msg ,findtype NPF -1 %Bag1 $ 
  Msg ,moveitem finditem 1 %backpack $ 
  Msg ,findtype NPF -1 %Bag1 $ 
  Msg ,moveitem finditem 1 %backpack $ 
  Msg ,findtype NPF -1 %Bag1 $ 
  Msg ,moveitem finditem 1 %backpack $ 
; take bandages 
  Msg ,findtype ZLF -1 %mainchest $ 
  Msg ,moveitem finditem 20 %backpack $ 
  wait %time , s 
Return 

Sub StoreOre 
  Event SysMessage Going to store ore. 
  Call Mining.cfg 4 
  FindItem ZLF 
  If #FINDKIND = -1 
  { 
    Msg ,findtype ZLF -1 %mainchest $ 
    Msg ,moveitem %finditem 20 %backpack $ 
    Wait 1s 
  } 
  FindOre: 
    Finditem DWJ_SZF_POF_GFF_BFF 
    If #FINDKIND = -1 
    { 
      Call Mining.cfg 3 
      Move *x *y 0 
      Return 
    } 
    If #FINDKIND = 1 
    { 
      Ignoreitem #FINDID 

      Goto FindOre 
    } 
    Msg ,moveitem #FINDID 5000 %mainchest $ 
    Wait 2s 
  Goto FindOre 
Return 

Sub Next 
  Set %square %square + 1 
  If %square > 8 
  { 
    Set %square 1 
    Call Mining.cfg 2 
  } 
  If %square = 1 
    Set %position s 
  If %square = 2 
    Set %position n 
  If %square = 3 
    Set %position w 
  If %square = 4 
    Set %position e 
  If %square = 5 
    Set %position sw 
  If %square = 6 
    Set %position ne 
  If %square = 7 
    Set %position se 
  If %square = 8 
    Set %position center 
  Return 

Sub CheckPikeAxe 
  FindItem NPF 
  If #FINDKIND = -1 
  { 
    Event SysMessage 3AKOH4u/\uCb KuPKu 
    Call Mining.cfg 4 
    Msg ,findtype NPF -1 %Bag1 $ 
    Msg ,moveitem finditem 1 %backpack $ 
    Msg ,findtype NPF -1 %Bag1 $ 
    Msg ,moveitem finditem 1 %backpack $ 
    Msg ,findtype NPF -1 %Bag1 $ 
    Msg ,moveitem finditem 1 %backpack $ 
    Wait 5s 
    FindItem NPF 
    If #FINDKIND = -1 
    { 
      Event SysMessage A 4EM MHE KOnATb ??? 
      Halt 
    } 
    Call Mining.cfg 3 
    Move *x *y 0 
  } 
Return 

Sub SaySomeSheet 
; шанс что чар что-то скажет 1 из 10 
  Set %randomize #random % 30 
  If %randomize = 0 
    GoSub WhatToSay 
  Return 

Sub WhatToSay 
; это случайные фразы что будет говорить чар 
; можно добавить сколько угодно 10 - количество фраз 
; чтоб добавить фразу просто допишите еще одно условие вида: 
; If %r = 11 
;    Msg "ваша фраза" $ 
; и так далее :) 

  Set %r #random % 10 
  If %r = 0 
    Msg : grrr $ 
  If %r = 1 
    Msg bla-bla-bla $ 
  If %r = 2 
    Msg :) $ 
  If %r = 3 
    Msg bI-bI-bI-bI $ 
  If %r = 4 
    Msg Xmm... $ 
  If %r = 5 
    Msg LOL $ 
  If %r = 6 
    Msg Mihoshi MAST DIE!!!!!! $ 
  If %r = 7 
    Msg CEP nJI3 HE rAHu 9I CBOu ! $ 
  If %r = 8 
    Msg BAC9I BuPy4u HA PU64uK $ 
  If %r = 9 
    Msg ggg $ 
  Return

CONDOMchick · Post by **CONDOMchick** » 2006-05-09 22:26:11

Ascoron wrote:Добавил в скрипт остальные руды...
Но оно чего-то не запускается
Code: Select all
... 
var pix='0x62C19316' 
... 
if uo.injournal("немного руды | Rusty | Old Copper | Dull Copper | Shadow | Merkite | Copper | Bronze | Silver | Rose | Agapite | Blood Rock |  Verite") then 
uo.deletejournal() 
uo.moveitem("pix", str(uo.getQuantity("pix")), uo.containerOf("pix"), str(uo.getX("pix")), str(uo.getY("pix")), str(uo.getZ("pix"))) 
...
Молвит "Line 1:parse error"

ЖЖОШ

CONDOMchick · Post by **CONDOMchick** » 2006-05-09 22:26:58

а чё за старнный скрипт на мининг?

DerMeister =) · Post by **DerMeister =)** » 2006-05-09 22:27:40

Это код под изю, а не под инжект!
А это разные веши! Вощем я имел ввиду что ты мне дашь код для инжекта, а я в него вделаю етот фокус с киркой... Изю я не знаю вообще...

You Must Die: Матом в соседнем форуме разговаривать будешь.

CONDOMchick · Post by **CONDOMchick** » 2006-05-09 22:29:50

Der wrote:Да блять ... Чё это за гавно? Это код под изю, а не под инжект!
А это разные веши! Вощем я имел ввиду что ты мне дашь код для инжекта, а я в него вделаю етот фокус с киркой... Изю я не знаю вообще...

ыы а я удивился...
а чё такое изю?

Ascoron · Post by **Ascoron** » 2006-05-09 22:31:02

Der wrote:Да блять ... Чё это за гавно? Это код под изю, а не под инжект!
А это разные веши! Вощем я имел ввиду что ты мне дашь код для инжекта, а я в него вделаю етот фокус с киркой... Изю я не знаю вообще...

У нас на шарде делают макросы на Изю с командами под инжект (более 90%)...
А чисто инжектовского макроса нету

DerMeister =) · Post by **DerMeister =)** » 2006-05-09 22:33:14

CONDOMchick wrote:
Der wrote:Да блять ... Чё это за гавно? Это код под изю, а не под инжект!
А это разные веши! Вощем я имел ввиду что ты мне дашь код для инжекта, а я в него вделаю етот фокус с киркой... Изю я не знаю вообще...

ыы а я удивился...
а чё такое изю?

EasyUO - программа на подобие инжекта, пилота и ассиста...
Больше похожа на всеми любимый инжект. Ты внатуре не знал? А как же команда uo.SetEasyUO(number,text)?? Вощем хелп читать надо (http://yoko.netroof.net/help/) там немножко про изю написано...

CONDOMchick · Post by **CONDOMchick** » 2006-05-09 22:33:34

Ascoron wrote:
Der wrote:Да блять ... Чё это за гавно? Это код под изю, а не под инжект!
А это разные веши! Вощем я имел ввиду что ты мне дашь код для инжекта, а я в него вделаю етот фокус с киркой... Изю я не знаю вообще...
У нас на шарде делают макросы на Изю с командами под инжект (более 90%)...
А чисто инжектовского макроса нету

млин чё за бред ты мутишь

скажи какой шард

Ascoron · Post by **Ascoron** » 2006-05-09 22:33:41

CONDOMchick wrote:ЖЖОШ

Я не нарошно

Ascoron · Post by **Ascoron** » 2006-05-09 22:34:25

CONDOMchick wrote:а чё за старнный скрипт на мининг?

Запусти этот макрос в EasyUO и посмотри... Довольно таки не плохой...

CONDOMchick · Post by **CONDOMchick** » 2006-05-09 22:34:28

Der wrote:
CONDOMchick wrote:
Der wrote:Да блять ... Чё это за гавно? Это код под изю, а не под инжект!
А это разные веши! Вощем я имел ввиду что ты мне дашь код для инжекта, а я в него вделаю етот фокус с киркой... Изю я не знаю вообще...

ыы а я удивился...
а чё такое изю?
EasyUO - программа на подобие инжекта, пилота и ассиста...
Больше похожа на всеми любимый инжект. Ты внатуре не знал? А как же команда uo.SetEasyUO(number,text)?? Вощем хелп читать надо (http://yoko.netroof.net/help/) там немножко про изю написано...

я понял уже просто как первые строки этого мокроса посмарел описание.

просто забыл ибо никогда не сталкивался

DerMeister =) · Post by **DerMeister =)** » 2006-05-09 22:35:04

Ascoron wrote:
Der wrote:Да блять ... Чё это за гавно? Это код под изю, а не под инжект!
А это разные веши! Вощем я имел ввиду что ты мне дашь код для инжекта, а я в него вделаю етот фокус с киркой... Изю я не знаю вообще...
У нас на шарде делают макросы на Изю с командами под инжект (более 90%)...
А чисто инжектовского макроса нету

Тогда ищи на этом форуме скрипт на мининг (тут из дох*я), который у тебя будет работать... Потом отпостишь его сюда и я тебе сделаю твой фокус с киркой.

Ascoron · Post by **Ascoron** » 2006-05-09 22:35:51

CONDOMchick wrote:
Ascoron wrote:
Der wrote:Да блять ... Чё это за гавно? Это код под изю, а не под инжект!
А это разные веши! Вощем я имел ввиду что ты мне дашь код для инжекта, а я в него вделаю етот фокус с киркой... Изю я не знаю вообще...
У нас на шарде делают макросы на Изю с командами под инжект (более 90%)...
А чисто инжектовского макроса нету
млин чё за бред ты мутишь
скажи какой шард

Уже писал...
Age of Power (AoP)
http://www.uo.net.ua/
http://www.ultima.kiev.ua/

CONDOMchick · Post by **CONDOMchick** » 2006-05-09 22:35:52

Ascoron wrote:
CONDOMchick wrote:а чё за старнный скрипт на мининг?
Запусти этот макрос в EasyUO и посмотри... Довольно таки не плохой...

дык инжу юзай и скрипты человечиские.
лгче такой
чтобы если идёт плохая руда он её выкидывал и шел на другую клетку.