Хочу чтоб он поднимал все быстро !

Sanata · Post by **Sanata** » 2006-03-08 02:16:32

Нужен скрипт:

Лежит много предметов (доспехи, рунбук и тд) и я хочу, чтобы он его поднял быстро!

Заранее спасибо!

Destruction · Post by **Destruction** » 2006-03-08 02:17:53

Конкретизируйте.

Edred · Post by **Edred** » 2006-03-08 11:51:33

Нужные типы забей в массив сам:

Code: Select all

#####################################################################
; AutoLootGround. v.1.11b (c) Edred
;
; Автоматически лутим с земли около чара. Одежду сразу режем на бинты.
;
sub AutoLootGround()
   VAR Cleaver = '0x0EC2'   ; кливер (тип)
   VAR Scissor = '0x0F9E'   ; Ножницы
   VAR fastloot = 'FastLoot detected.'
   DIM Nado[27]
   Nado[0]  = '0x170B'   ; boots
   Nado[1]  = '0x1718'   ; 
   Nado[2]  = '0x1516'   ; a skirt
   Nado[3]  = '0x1F03'   ; a robe
   Nado[4]  = '0x1F01'   ; a plain dress
   Nado[5]  = '0x1EFD'   ; a fancy shirt
   Nado[6]  = '0x1541'   ; a body sash
   Nado[7]  = '0x170B'   ; boots
   Nado[8]  = '0x170D'   ; sandals
   Nado[9]  = '0x1717'   ; a straw hat
   Nado[10] = '0x1539'   ; long pants   
   Nado[11] = '0x152E'   ; short pants
   Nado[12] = '0x1515'   ; a cloak
   Nado[13] = '0x1FA1'   ; tunic
   Nado[14] = '0x0EED'   ; gold coin
   Nado[15] = '0x0F3F'   ; arrows
   Nado[16] = '0x0F7A'   ; pearls, black pearls
   Nado[17] = '0x0F7B'   ; bood moss
   Nado[18] = '0x0F7D'   ; vials of blood
   Nado[19] = '0x0F84'   ; garlic
   Nado[20] = '0x0F85'   ; ginseng
   Nado[21] = '0x0F86'   ; mandrake root
   Nado[22] = '0x0F88'   ; night shade
   Nado[23] = '0x0F8C'   ; sulphorous ash
   Nado[24] = '0x0F8D'   ; spiders silk
   Nado[25] = '0x14ED'   ; a treasure map
   Nado[26] = '0x0E75'   ; backpack
   VAR i
   UO.Exec( 'set finddistance 3' )
   For i = 0 To 25
      UO.FindType( Nado[i], '-1', '1' )
      While UO.FindCount() > 0
         DeleteJournal( fastloot )
         If i < 14 Then
            UO.WaitTargetObject( 'finditem' )
            UO.UseType( Scissor )
            GetPause(500)
            CheckLag()
         Else
            If i == 23 Then
               If UO.GetQuantity( 'finditem' ) == 1 Then
                  UO.Ignore( 'finditem' )
               Else
                  UO.MoveItem( 'finditem' )
                  GetPause(350)
                  CheckLag()
               Endif
            Else
               UO.MoveItem( 'finditem' )
               GetPause(350)
               CheckLag()
            Endif
         Endif
         UO.FindType( Nado[i], '-1', '1' )
      Wend
   Next
   UO.Print( 'The loot was finished' )
endsub

;
; Пауза в переданных миллисекундах, с проверкой на сообщение о
; детекте фастлута. Не забудьте удалить эту фразу из журнала перед
; тем действием, после которого стоит эта пауза!
Sub GetPause( ms )
   VAR t = 0
   VAR msg = 'FastLoot detected.'
   repeat
      wait(50)
      t = t + 50
   until t >= ms OR UO.InJournal( msg )
   If UO.InJournal( msg ) Then
      wait(200)
   Endif
endsub

Sub CheckLag()
   DeleteJournal( 'backpack' )
   UO.Click( 'backpack' )
   repeat
      wait(100)
   until UO.InJournal( 'backpack' )
   return
end sub

Sub DeleteJournal( string1 )
   VAR nom = UO.InJournal( string1 )
   If nom > 0 Then
      UO.SetJournalLine( Nom - 1, 'string replaced' )
      DeleteJournal( string1 )
   Endif
endsub

Destruction · Post by **Destruction** » 2006-03-08 16:15:49

Нех конкретизировать?

Начит попробую представить, лежит куча хлама... в сумке...

Намёк понял!?

Edred · Post by **Edred** » 2006-03-09 00:49:44

LordTom wrote:

Code: Select all

sub all()
uo.exec('set finddistance 2')


uo.findtype('-1' ,'-1','ground')
   while UO.FindCount() > 0
   uo.findtype('-1','-1','ground')   
      if uo.getserial('finditem') <> uo.getserial('self')
      uo.moveitem('finditem','0','backpack') 
      wait(300) 
      endif
   wend
endsub

Нех тут конкретезироовать.

Классный скрипт. Возьми его и иди в данж. Запусти. Посмотрим, сколько у тебя чар простоит в попытках засунуть в бекпак трупы, монстров, прилоченные предметы, других чаров, лошадь и прочее...

Edred · Post by **Edred** » 2006-03-09 12:01:11

LordTom wrote:Я юзаю его после макросов с кучей всякого хлама на полу. Епта этот скрипт не под пвп и пвм, и тошо он буит глючить на всякой прилочке ясен пень. Но на лодке собрать вся хрень вполне подойдет

И что, он у тебя не зацикливается на попытке засунуть в бекпак лодку или трюм? :shock:

Don SpiL · Post by **Don SpiL** » 2006-03-09 12:19:27

Дестракшена разорвали просто! Вот после таких скриптофф....
ЕмаЁ самый проверенный временем способ лутить\собирать с пола только лишь то что прописано в скрипте просто перебирая типы и пытаться поднять их! плюс не забываем ставить проверки на "ту фар авей" и так далее!Ну и естественно задержа между поднятиями должна быть!

Sanata · Post by **Sanata** » 2006-03-09 22:30:10

LordTom wrote:
Code: Select all
собирать с пола только лишь то что прописано
вот епт! умные какие.
А теперь скажите, как под "точто прописана" подставить сабж "хочу чтобы все подымало" дать скрипт?? Хочет всё? получит на все:)
А тошо будет глюкать, никатит)

прям в : .

Sanata · Post by **Sanata** » 2006-03-09 22:31:05

Sanata wrote:
LordTom wrote:
Code: Select all
собирать с пола только лишь то что прописано
вот епт! умные какие.
А теперь скажите, как под "точто прописана" подставить сабж "хочу чтобы все подымало" дать скрипт?? Хочет всё? получит на все:)
А тошо будет глюкать, никатит)
прям в : .

(точку)

R e s p e c t вам всем !

Don SpiL · Post by **Don SpiL** » 2006-08-21 19:19:51

Умные? да ты прав! Я не устраиваю тут писькомер...я только хотел помочь человеку а не то чтобы ты оценивал мои умственные способности!

Sfagnum · Post by **Sfagnum** » 2006-08-21 22:17:35

uo.findtype(-1,-1,'ground') - не найдёт фулы и часть др вещей на ДРВ.
+ скорость мжн повысить.