Нужен скрипт на БС дагеров

[asder]

Нужен скрипт на блексмитинг дагера... помогите кто-то

[stickman]

поиск рулит!

Code: Select all

##################
# Black Smithing #
##################
#
# Ignots on the ground. Smith hammer on the right hand.
# We're standing near a forge, which we'll target and
# near ingots. If you can't find ingots - ,set finddistance 10
# When a quantity of produced item more than 20 -smelthing
# for ingots.
# 21.12.06 .Tested on shard Dragon World
#
sub BlackSmithingYMD()
 var IngType=0x1BEF # Type of ignots to smith
 var IngColor=0x0000 # Color of ingots to smith
 var Item=0x1410 # Type of a produced item
 uo.AddObject('Forge')
 while uo.Targeting()
   wait(100)
 wend
  while uo.SkillVal('Blacksmithing','1') < 1000
    uo.DeleteJournal()
    uo.FindType(IngType,IngColor,'backpack')
    if not uo.FindCount() || uo.GetQuantity('finditem') < 50 then
      GetItem(IngType,IngColor,500,'ground','backpack')
    end if
    uo.WaitMenu('Black','Weapons','Weapons','Swords','Swords','dagger') # Change
    uo.UseObject('finditem')
    repeat
      wait(100)
    until uo.InJournal('put') || uo.InJournal('fail')
    if uo.InJournal('put') then
      uo.FindType(Item,'-1','backpack')
      if uo.FindCount() > 20 then
        while uo.FindCount()
          uo.WaitTargetObject('finditem')
          uo.UseObject('Forge')
          wait(750)
          uo.FindType(Item,'-1','backpack')
        wend
      end if
      wait(50)
    end if
  wend
end sub

###########
# GetItem #
###########

sub GetItem(type, color, quantity, where , to)
  uo.FindType(type,'-1',where)
  if uo.FindCount() then
    uo.moveitem('finditem',quantity,to)
    wait(750)
  end if
end sub