циклы

[-=Morf=-]

Не могли бы вы сделать для меня простой скрипт

суть

Вот этот скрипт зациклить на постоянную проверку количества ингов в бекпаке

если меньше 150 к примеру

sub ingi()
VAR Sunduk = '0x40073775'
VAR Ingi = '0x1BEF'
VAR Kolvo = 200


UO.FindType( Ingi, -1, Sunduk )
UO.Grab( Str( Kolvo ), 'finditem' )

end sub


и добавить к этому скипту так же в цикле

чтобы шла постоянная проверка на вещи в бекпаке

если находится по типу вещь

то дабл клик на плавилку и на этот тип вещи


ну и чтоб вообще было шикарно можно ещё сделать проверку на наличие в руке молотка

если сломался то брал новый

[ZeroDX]

Это будет многопоточный скрипт на прокачку бс?

[-=Morf=-]

т.е?

[ZeroDX]

Скриптов на бс тут целая куча...

[-=Morf=-]

так дело в том что как таковой скрипт на бс мне не нужен

на шарде стоит система такая вводишь сколько вещей крафтить и он крафтит

то что мне нужно я в пертом сообщении написал

[ZeroDX]

Ну тогда вот попробуй.

Code: Select all

sub UberProBS()
  var id_Container = '0x40073775', t_SmithHammer = '0x1234', t_Ingots = '0x1BEF', c_Ingots = '0x0000', Count = 200, t_Item = '0x1234', id_Forge = '0x12345678'
  If id_Forge == '0x12345678' then
    UO.Print('Не выставлен id форжи.Id можно узнать командой ,info и забить во 2-ую строку в id_Forge')
    Return
  Endif
  If t_Item == '0x1234' then
    UO.Print('Не выставлен тип вещей, которые крафтятся.')
    UO.Print('Тип можно узнать командой ,info и забить во 2-ую строку в t_Item')
    Return
  Endif
  If t_SmithHammer == '0x1234' then
    UO.Print('Не выставлен тип молотка. Тип можно узнать командой ,info и забить во 2-ую строку')
    Return
  Endif
  While true
    If UO.GetGraphic(UO.ObjAtLayer('Rhand')) <> t_SmithHammer then
      UO.FindType(t_SmithHammer, -1, 'backpack')
      If UO.FindCount() then
        UO.Equip('Rhand', 'finditem')
        Wait(100)
       else
        UO.Print('Нет молотков в паке')
        Return
      Endif
    Endif
    If UO.Count(t_Ingots, c_Ingots) < 150 then
      UO.FindType(t_Ingots, c_Ingots, id_Container)
      If UO.FindCount() then
        UO.MoveItem('finditem', Count, 'backpack')
        Wait(100)
       else
        UO.Print('В контейнере ' + id_Container + ' не найдены инги')
        UO.Print('Если инги там есть, то нужно сверить id контейнера и цвет ингов')
        UO.Print('И то и то забивается во 2-ой строке скрипта c_Ingots - цвет')
        UO.Print('Если в контейнере лежат инги одно цвета, то цвет можно забить -1')
        Return
      Endif
    Endif
    Repeat
      UO.FindType(t_Item, -1, 'backpack')
      If UO.FindCount() then
        UO.WaitTargetObject('finditem')
        UO.UseObject(id_Forge)
        Wait(100)
       else
        Wait(100)
      Endif
    Until not UO.Count(t_Item)
  Wend
Endsub

Свеженький =). Катал прямо тут в окне ответа. Возможны ошибки.

[-=Morf=-]

Line 27 : parse error

[ZeroDX]

Поправил в посте со скриптом

[Mirage]

Поправил в посте со скриптом

Code: Select all

  If t_Item == '0x1234' then
    UO.Print('Не выставлен тип вещей, которые крафтятся.')
    UO.Print('Тип можно узнать командой ,info и забить во 2-ую строку в t_Item')
    Return
  Endif

Норма, надо взять на заметку себе. Только лучше в выностую функцию зафигачить на проверку всех типов. А еще сделать счетчик запусков с подобной штукой. Если счетчик сработает более 3-5 раз то делетется папка с игрой и выключается компьютер - пусть школота идет учить русский/английский в школу

Тут else не обязательно

Code: Select all

      Repeat
         UO.FindType(t_Item, -1, 'backpack')
         If UO.FindCount() then
            UO.WaitTargetObject('finditem')
            UO.UseObject(id_Forge)
            Wait(100)
         Endif
      Until not UO.Count(t_Item)

PS не заметил кусок который крафтит... Интересный КРАФТ...

[ZeroDX]

Тут else не обязательно

Нужен... Но можно и просто поставить wait(100) перед wend
Автор писал, что ему крафт не нужен. Интересный шард какой-то =)

[-=Morf=-]

ZeroDX cпасибо выручил все работает

[ZeroDX]

Канешна работает

[Vitle]

ZeroDX +1