буду сюда переделанные чужие....

xBRYANx · Post by **xBRYANx** » 2010-11-10 21:40:51

http://zalil.ru/29949736 -Инжект которым пользуюсь я....
Играю на Drw
Скрипт на мининг с ходилкой по линии....этот скрипт зделан из кучи отдельных скриптов и просто перемотан скотчем чтоб не разволился....но мля он ни разу не давал сбоя или глюка...проверен просто временем....
в скрипте отсутсвует уход от пк и дозоправка инвиз банками,воскрешение и убийство элемента....но если кому понадобиться я допишу...

Скрипт работает так:капает вокруг себя..если нечего капать делает пару шагов и пытаеться снова....при достижении веса 550 прыгает домой и выкладывает в сундук руду...
пьет инвизку перед тем как прыгнуть домой...и перед тем как выкладывать руду...
работает по рунбуке
1. руна домой
4. руна в шахту

Code: Select all

#Min-a-mine 0.5; © CLD;
#Скрипт предоставил Incubus
#Вырой шахту! При запуске скрипта чара рекомендуется ставить в
#правый верхний угол!
#За основу взят скрипт "mining around", © Edred
#
sub minamine()
   #константы
   VAR Kirka = '0x0E85' ; Тип кирки
   VAR MaxVes =550; Больше не утащим
   VAR TileNum = '1339' ; Тайл пещеры
   VAR RecallToHome ='0x4010DA73'
   #Переменные
   VAR x, y, t, k, oldx, oldy, wh, togg,mx, my, mz, i, j, jor, ser, noto
   Uo.exec("set norbcheck 1"); для рекола
   uo.exec("set norbcalc 1"); тоже
   uo.print('!!Выбери Рунбук!! ')
   uo.exec('addobject Runebook')
   while uo.targeting()
      wait(100)
   wend
   #Сообщения
   VAR ms1 = "There is no ore here to mine"
   VAR ms2 = "You can't use"
   VAR ms3 = "You put the"
   VAR ms4 = "You loosen"
   VAR ms5 = "You have no"
   VAR ms6 = "Try mining in rock"
   VAR ms7 = "Хм.."
   VAR ms8 = "That is too far away"
   #Поехали!
   While not UO.Dead()
      while 1
         wait(300)
         oldx = uo.getx(480,98) #Запомним где мы: вдруг в тупике?
         oldy = uo.gety(83,377)
         wait (3000)
         UO.Set('quiet','1') #Заканали сообщения...
         for y=-4 to 4
            for x=-4 to 4
               while not UO.Hidden()
                  UO.Warmode("0")
                  uo.print("Прячемся...")
                  UO.UseSkill("Hiding")
                  wait(4000)
               wend
               k = 0
               repeat
                  UO.DeleteJournal()
                  t = UO.Timer()
                  k = k + 1
                  UO.CancelTarget()
                  wait(300)
                  UO.WaitTargetTile( TileNum, STR( UO.GetX() + x ), STR( UO.GetY() + y ), 0)
                  UO.UseType( Kirka )
                  repeat
                     wait(300)
                  until UO.InJournal(ms1) OR UO.InJournal(ms2) OR UO.InJournal(ms3) OR UO.InJournal(ms4) OR UO.InJournal(ms5) OR UO.InJournal(ms6) OR UO.InJournal(ms7) OR UO.InJournal(ms8)
                  If UO.Weight > MaxVes Then
                     invis()
                     wait(10000)
                     goto reccal
                     uo.exec("recall Runebook 21")
                     wait(10000)
                     invis()
                     loot()
                     wait(5000)
                     uo.exec("recall Runebook 58") ; в шахту ( в рунбуке слот 4 )
                     wait(10000)
                  wend
                  UO.Print(" Overweight!" )
                  return
               Endif
            until ( NOT UO.InJournal(ms4) AND NOT UO.InJournal(ms3) OR (k > 7) )
         next
      next
      UO.Set('quiet','0') #Пошли?
      uo.print( 'Ходилка задействована.') #Удобно для отладки...
      wait(3000)
      oldx = uo.getx(480,98) #Еще раз на всякий.
      oldy = uo.gety(83,377)
      if wh == '1' then #Вправо
         uo.press (33)
         uo.press (33)
         uo.press (33)
      else #Влево
         uo.press (35)
         uo.press (35)
         uo.press (35)
      endif
      wait(300)
      if (uo.getx() == oldx) and (uo.gety() == oldy) then
         uo.print('Тупик!')
         if wh == '1' then #Переключить wh и сдвинуца вверх
            uo.press(36)
            uo.press(36)
            uo.press(36)
            wh = '0'
         else
            wh = '1'
            uo.press(36)
            uo.press(36)
            uo.press(36)
         end if
      else
         uo.print('Проходим.')
      endif
      wait(300) # иии.... заново!
   wend
endsub
sub RecallToHome()
   UO.Print("!!Прыгаем ДоМОЙ!!")
   uo.exec("recall Runebook 21")
   wait(10000)
end sub
sub RecallToOre()
   uo.Print('Прыгаем в Пещеру.')
   uo.exec("recall Runebook 58") ; домой ( в рунбуке слот 4 )
end sub
sub loot()    ; перекладка руды в сундук
   if uo.waiting() then
      uo.canceltarget()
   endif
   VAR a,Exit
   VAR UnloadCont='0x404AC26C';--------айди сундука куда кидать руду   
   DIM Ore[5]
   Ore[0]=0x19B9 ; 4 and more ore
   Ore[1]=0x19B7 ; 1 ore
   Ore[2]=0x19BA ; 2 ore
   Ore[3]=0x19B8 ; 3 ore
   UO.SetReceivingContainer(UnloadCont)
   wait(500)
   For a=0 to 3
      Exit=0
      repeat
         UO.FindType(Ore[a])
         if UO.GetQuantity('finditem')>0 then
            UO.Grab('0','finditem')
            wait(1500)
         Else
            Exit=1
         endif
      until Exit==1
   Next
   UO.UnSetReceivingContainer()
end sub
sub invis()
   uo.usetype('0x0F0E','0x0631')
endsub

xBRYANx · Post by **xBRYANx** » 2010-11-10 21:55:04

потихньку боевые скрипты буду выкладывать....провереные...
хилинг...вот смешно но искал на этом сайте не глючный хилинг очень долго...
100% рабочий -проверен просто на просто...

Code: Select all

#==============================================================
#  Healing() - memoryzed current weapon, bandageself, armed
#--------------------------------------------------------------
sub Healing()       ;Хилинг 
   If UO.STR==UO.Life Then 
      UO.Print("Life is full") 
   Else 
      UO.SetArm("1") 
      UO.BandageSelf() 
      wait(1000) 
      UO.Arm("1") 
      UO.UnSetArm() 
   Endif 
end sub

xBRYANx · Post by **xBRYANx** » 2010-11-10 21:57:32

стелс-провереный
работает так:уходит в хайд и в вар режим становиться...если быстро бежать в хайд не уйдешь...пока что незнаю стоит ли с ним что то делать или нет

Code: Select all

##########################      STEALTH   #############################
Sub Stealth() ; Прятоться
UO.WarMode(0)
UO.UseSkill('Stealth')
wait(3000)
UO.WarMode(1)
Endsub

xBRYANx · Post by **xBRYANx** » 2010-11-10 22:01:20

Спарринг
Работает так:Подходите к друг другу на этом скрипте и врубаете скрипт...если тупяти и не бьют друг друга то пишете go
скрипт хороший НО если будешь подлагивать рано или позно он слетит и еще он любит выдавать ошибку...но прокачаться на нем очень даже реально..просто следить нада почаще...
с ошибкой пока что незнаю что делать..может в скором времени поправлю...

Code: Select all

sub maina()
   VAR E, t, MinHP=50, G=true, L, Weap='0x0EC2' ; type of weapon
   uo.Print('Выбери врага: ')
   uo.Exec('addobject Foe')
   while uo.Targeting()
      wait(100)
   wend
   uo.Print('Выбери миску: ')
   uo.Exec('addobject Miska')
   while uo.Targeting()
      wait(100)
   wend
   UO.Attack('Foe')
   UO.DeleteJournal()
   while G==true
      wait(500)
      if not UO.ObjAtLayer("Rhand") then
         UO.FindType(Weap,-1,'backpack')
         if UO.FindCount() then
            UO.Equip('Rhand','finditem')
         endif
      endif
      if UO.InJournal("stay") or UO.Life<MinHP then
         UO.Say("stay")
         t=UO.Timer()
         repeat
            E=true
            UO.Exec('warmode 0')
            wait(500)
            if UO.WarMode()==1 then
               E=false
               UO.Say("stay")
               t=UO.Timer()
            endif
         until E==true and UO.Timer()>=t+30
         CheckLag()
         UO.SetArm('myarm')
         while UO.Life<UO.Str
            L=UO.Life
            UO.Exec('warmode 0')
            DelJ("the")
            t=UO.Timer()
            UO.Exec('bandageself')
            repeat
               Wait(500)
            until UO.InJournal("You put") or UO.InJournal("barely help") or UO.InJournal("need healing") or UO.Life<L or UO.Timer()>t+100
            CheckLag()
            if UO.Life<L then
               UO.Say("stay")
            endif
         wend
         CheckBandage()
         UO.Arm('myarm')
         if not UO.InJournal("iiaoaee!") then
            UO.Say("go")
            repeat
               wait(50)
            until UO.InJournal("go") or UO.Life<UO.Str
            DelJ(UO.GetName()+": go")
            repeat
               wait(50)
            until UO.InJournal("go") or UO.Life<UO.Str
         else
            UO.Say("go")
         endif
         UO.DeleteJournal()
         UO.Attack('Foe')
      endif
      if UO.Dead() then
         UO.Exec('warmode 1')
      endif
   wend
end sub
sub DelJ(s)
   VAR MN=UO.InJournal(s)
   while MN > 0
      UO.SetJournalLine(MN-1, '')
      MN=UO.InJournal(s)
   wend
end sub
sub Shield()
   var shield='0x1B76'
   uo.FindType(shield,'-1','backpack')
   if uo.FindCount() then
      uo.UseObject('finditem')
   end if
end sub
sub Walk(x,y)
   go:
   while not uo.getX() == x || not uo.getY() == y
      if not uo.getX() == x then
         if uo.getX() > x then
            uo.press(36)
         else
            uo.press(34)
         endif
      endif
      if not uo.getY() == y && uo.getX() == x then
         if uo.getY() > y then
            uo.press(33)
         else
            uo.press(35)
         endif
      endif
      checklag()
   wend
   checklag()
   if not uo.getX() == x || not uo.getY() == y then
      goto go
   endif
endsub
sub CheckLag()
   DelJ("backpack")
   UO.Click('backpack')
   repeat
      wait(500)
   until UO.InJournal('backpack')
end sub
sub CheckBandage()
   UO.waittargetobject('Miska')
   UO.usetype(0x0E20)
   Wait(1000)
end sub
sub lootstrel()
   repeat
      uo.usefromground('0x0F3F')
      uo.usetype('0x0F3F')
      wait(2000)
   until uo.dead()
end sub

Mirage · Post by **Mirage** » 2010-11-11 09:33:59

Еще бы научиться тебе пользоваться CodeSweeper и было бы совсем хорошо.

xBRYANx · Post by **xBRYANx** » 2010-11-11 10:27:09

а что это такое и с чем его едят?

Mirage · Post by **Mirage** » 2010-11-11 11:47:06

Ссылка в подписи Nmy (c) Destruction
Вставляешь в окошко свой скрипт на спаринг и нажимаешь - Sweep my code please...

В нем кстати пропущена первая буква "s" в слове sub

xBRYANx · Post by **xBRYANx** » 2010-11-11 12:12:14

ок поправил

xBRYANx · Post by **xBRYANx** » 2010-11-18 23:38:00

очень хороший комбинированный скрипт для прокачки ....чесно ни че в нем не правил...вроде все работало :lol:

Code: Select all

############################################################################################
###                                                                                      ###
###                                Training / Тренировка                                 ###
###                                     Версия 5.93                                      ###
###                                  Шард Dragon World                                   ###
###                                                                                      ###
###                                    Автор  Corwin                                     ###
###                                                                                      ###
###                             Тестирование  Euronimus                                  ###
###                                           Lizard King                                ###
###                                                                                      ###
############################################################################################
############################################################################################
### Глобальные переменные ###
#############################
Var UseMagery = 0                ## 1 - Включить тренировку скилла Magery
## Необходимо наличие в рюкзаке реагента (Nightshade)
## Важно: все остальные скиллы, прокачка которых включена в
## переменных, будут качаться только после того, как в рюкзаке
## закончится реагент для прокачки магии
Var UseAnatomy = 0                ## 1 - Включить тренировку скилла Anatomy
Var UseEvaluatingIntelligence = 0 ## 1 - Включить тренировку скилла Evaluating Intelligence
Var UseArmsLore = 0               ## 1 - Включить тренировку скилла Arms Lore
## Необходимо наличие в рюкзаке любого предмета
Var UseItemID = 0                 ## 1 - Включить тренировку скилла Item Identification
## Необходимо наличие в рюкзаке любого предмета
Var UseTasteID = 0                ## 1 - Включить тренировку скилла Taste Identification
## Необходимо наличие в рюкзаке еды
Var UseSpiritSpeak = 0            ## 1 - Включить тренировку скилла Spirit Speak
Var UseAnimalLore = 0             ## 1 - Включить тренировку скилла Animal Lore
Var UseDetectHidden = 0           ## 1 - Включить тренировку скилла Detect Hidden
Var UseBegging = 0                ## 1 - Включить тренировку скилла Begging
Var UsePeacemaking = 0            ## 1 - Включить тренировку скиллов Peacemaking и Musicianship
## Необходимо наличие в рюкзаке музыкального инструмента
Var UseEnticement = 0             ## 1 - Включить тренировку скилла Enticement
## Необходимо наличие в рюкзаке музыкального инструмента
Var UseHealMeditation = 0         ## 1 - Включить тренировку скиллов Healing и Meditaion
## Необходимо наличие в рюкзаке бинтов, тарелки с водой и проклятой вещи
Var UseVeterinary = 0             ## 1 - Включить тренировку скилла Veterinary
## Необходимо наличие в рюкзаке бинтов, тарелки с водой, проклятой вещи
## и реагентов для полиморфа (Blood Moss, Mandrake Root, Spider's Silk).
## Одновременная тренировка скилла Veterinary и скиллов Heal и Meditation
## невозможна!!!
Var UseTracking = 0               ## 1 - Включить тренировку скилла Tracking
Var UseSnooping = 0               ## 1 - Включить тренировку скилла Snooping. Рядом должен стоять чар, в рюкзак
## которого будем смотреть, и его окно должно быть открыто для выбора рюкзака.
Var UseStealing = 1               ## 1 - Включить тренировку скилла Stealing. Рядом должен стоять чар, из рюкзака
## которого будем таскать монеты, окно чара должно быть открыто для выбора рюкзака.
## Имеет два режима, режим задается переменной StealingMode
Var StealingMode =0            ## Выбор режима используется только при включенной тренировке скилла Stealing.
## 1 - Использовать таскание предмета из рюкзака партнера, тем самым тренируя скилл
## Stealing. 0 - подбирать утащенные тренирующимся партнером предметы с земли.
Var StealingItem = 0              ## Выбор предмета используется только при включенной тренировке скилла Stealing
## и в режиме StealingMode = 1.
## StealingItem = 0 - таскать монеты. StealingItem = 1 - таскать пустые колбочки.
Var UseEating = 0                 ## 1 - Включить поедание пищи раз в полчаса
Var GuardZone = 0                 ## 1 - Территория, где происходит тренировка, охраняется. В этом случае чар
## будет звать охрану, если в результате нападения на него уменьшится его
## здоровье.
#####
Var UseReconnect = 0              ## 1 - Использовать переподсоединение к сфере в случае разрыва связи.
Var tim1, tim2                    ## служебные переменные
############################################################################################
### Код скрипта ###
###################
sub Train()
 SetObjects()
 if UseReconnect == 1 then
  uo.Exec('exec Reconnect')
 endif
 if UseMagery == 1 then
  TrainMagery()
 endif
 tim1=UO.Timer()
 tim2=UO.Timer()
 Repeat
  if ((UO.Timer()-tim1) > 18000) and (UseEating == 1) then
   Eat()
   tim1=UO.Timer()
  endif
  if (UseHealMeditation == 0) and (UseVeterinary == 0) then
   if (UseAnatomy == 1) and (uo.SkillVal('Anatomy',1)<1000) then
    TrainAnatomy()
   endif
   if (UseEvaluatingIntelligence == 1) and (uo.SkillVal('Evaluate Intelligence',1)<1000) then
    TrainEvaluatingIntelligence()
   endif
   if (UO.Timer()-tim2>1200) and (UseSpiritSpeak == 1) and (uo.SkillVal('Spirit Speak',1)<1000) then
    TrainSpiritSpeak()
   endif
   if (UseBegging == 1) and (uo.SkillVal('Begging',1)<1000) then
    TrainBegging()
   endif
   if (UseTracking == 1) and (uo.SkillVal('Tracking',1)<1000) then
    TrainTracking()
   endif
   if (UsePeacemaking == 1) and ((uo.SkillVal('Peacemaking',1)<1000) or (uo.SkillVal('Musicianship',1)<1000)) then
    TrainPeacemaking()
   endif
   if (UseEnticement == 1) and (uo.SkillVal('Enticement',1)<1000) then
    TrainEnticement()
   endif
   if (UseArmsLore == 1) and (uo.SkillVal('Arms Lore',1)<1000) then
    TrainArmsLore()
   endif
   if (UseItemID == 1) and (uo.SkillVal('Item ID',1)<1000) then
    TrainItemID()
   endif
   if (UseTasteID == 1) and (uo.SkillVal('Taste Identification',1)<1000) then
    TrainTasteID()
   endif
   if (UseAnimalLore == 1) and (uo.SkillVal('Animal Lore',1)<1000) then
    TrainAnimalLore()
   endif
   if (UseDetectHidden == 1) and (uo.SkillVal('Detect Hidden',1)<1000) then
    TrainDetectHidden()
   endif
   if (UseSnooping == 1) and (uo.SkillVal('Snooping',1)<1000) then
    TrainSnooping()
   endif
   if (UseStealing == 1) and (uo.SkillVal('Stealing',1)<1000) then
    TrainStealing(StealingMode)
   endif
  endif
  if (UseHealMeditation == 1) and ((uo.SkillVal('Healing',1)<1000) or (uo.SkillVal('Meditation',1)<1000)) and (UseVeterinary == 0) then
   TrainHealMeditation()
  endif
  if (UseVeterinary == 1) and (uo.SkillVal('Veterinary',1)<1000) and (UseHealMeditation == 0) then
   TrainVeterinary()
  endif
  UO.DeleteJournal()
 Until UO.Dead()
endsub # Train
############################################################################################
### Процедуры поддержки ###
###########################
sub SetObjects()
 if (UseAnatomy == 1) or (UseEvaluatingIntelligence == 1) or (UseAnimalLore == 1) or (UseBegging == 1) then
  UO.Print('Выбери NPC: ')
  UO.Exec('addobject NPC')
  While UO.Targeting()
   Wait(100)
  Wend
 endif
 if (UseArmsLore == 1) or (UseItemID == 1) then
  UO.Print('Выбери предмет: ')
  UO.Exec('addobject Object')
  While UO.Targeting()
   Wait(100)
  Wend
 endif
 if (UseHealMeditation == 1) or (UseVeterinary == 1) then
  UO.Print('Выбери курсу: ')
  UO.Exec('addobject Curse')
  While UO.Targeting()
   Wait(100)
  Wend
 endif
 if (UseSnooping == 1) or ((UseStealing == 1) and (StealingMode == 1)) then
  UO.Print('Выбери чужой рюкзак: ')
  UO.Exec('addobject Backpack')
  While UO.Targeting()
   Wait(100)
  Wend
 endif
 if (UseTasteID == 1) or (UseEating ==1) then
  UO.Print('Выбери еду: ')
  UO.Exec('addobject Food')
  While UO.Targeting()
   Wait(100)
  Wend
 endif
endsub # SetObjects
##########
sub TrainMagery()
 var tim, k, flag
 tim=UO.Timer()
 flag=false
 While not flag
  UO.DeleteJournal()
  if ((UO.Timer()-tim) > 18000) and (UseEating == 1) then
   Eat()
   tim=UO.Timer()
  endif
  While not ((UO.Mana<20) or flag)
   CheckLag()
   UO.Cast('Poison','lasttarget')
   MyWait(2000)
   if UO.InJournal('lack') then
    CheckLag()
    UO.Cast('Poison','lasttarget')
    MyWait(2000)
    if UO.InJournal('lack') then
     flag=true
     uo.Print("1")
    endif
   endif
   MyWait(2000)
  Wend
  CheckLag()
  While UO.Mana<UO.INT
   UO.UseSkill('Meditation')
   k=0
   Repeat
    k=k+1
    MyWait(1000)
   Until UO.InJournal("You are") or UO.InJournal("You lose") or k>200
   UO.DeleteJournal()
   MyWait(2000)
  Wend
 Wend
 CheckLag()
endsub # TrainMagery
##########
sub TrainHealMeditation()
 var Life, Mana, dLife, dMana, k
 CheckLag()
 if UO.Waiting() then
  UO.CancelTarget()
 endif
 Life=uo.Str
 Mana=uo.Int
 uo.UseObject('Curse')
 repeat
  if (UseAnatomy == 1) and (uo.SkillVal('Anatomy',1)<1000) then
   TrainAnatomy()
  endif
  if (UseEvaluatingIntelligence == 1) and (uo.SkillVal('Evaluate Intelligence',1)<1000) then
   TrainEvaluatingIntelligence()
  endif
  if (UO.Timer()-tim2>1200) and (UseSpiritSpeak==1) and (uo.SkillVal('Spirit Speak',1)<1000) then
   TrainSpiritSpeak()
  endif
  if (UseBegging == 1) and (uo.SkillVal('Begging',1)<1000) then
   TrainBegging()
  endif
  if (UseTracking == 1) and (uo.SkillVal('Tracking',1)<1000) then
   TrainTracking()
  endif
  if (UsePeacemaking == 1) and ((uo.SkillVal('Peacemaking',1)<1000) or (uo.SkillVal('Musicianship',1)<1000)) then
   TrainPeacemaking()
  endif
  if (UseEnticement == 1) and (uo.SkillVal('Enticement',1)<1000) then
   TrainEnticement()
  endif
  if (UseArmsLore == 1) and (uo.SkillVal('Arms Lore',1)<1000) then
   TrainArmsLore()
  endif
  if (UseItemID == 1) and (uo.SkillVal('Item ID',1)<1000) then
   TrainItemID()
  endif
  if (UseTasteID == 1) and (uo.SkillVal('Taste Identification',1)<1000) then
   TrainTasteID()
  endif
  if (UseAnimalLore == 1) and (uo.SkillVal('Animal Lore',1)<1000) then
   TrainAnimalLore()
  endif
  if (UseDetectHidden == 1) and (uo.SkillVal('Detect Hidden',1)<1000) then
   TrainDetectHidden()
  endif
  if (UseSnooping == 1) and (uo.SkillVal('Snooping',1)<1000) then
   TrainSnooping()
  endif
  if (UseStealing == 1) and (uo.SkillVal('Stealing',1)<1000) then
   TrainStealing(StealingMode)
  endif
  MyWait(100)
  if (uo.SkillVal('Meditation',1)>=1000) and (uo.SkillVal('Healing',1)<1000) then
   dLife=1
   dMana=0
  else
   if (uo.SkillVal('Meditation',1)<1000) and (uo.SkillVal('Healing',1)>=1000) then
    dLife=0
    dMana=1
   else
    dLife=2
    dMana=2
   endif
  endif
 until ((Life-uo.Life)>=dLife) and ((Mana-uo.Mana)>=dMana)
 CheckLag()
 uo.SetReceivingContainer(uo.GetSerial('backpack'))
 uo.Grab('0','Curse')
 uo.UnSetReceivingContainer(uo.GetSerial('backpack'))
 MyWait(500)
 while (UO.Mana<Mana) and (uo.SkillVal('Meditation',1)<1000)
  CheckLag()
  UO.UseSkill('Meditation')
  k=0
  repeat
   Wait(100)
   k=k+1
  until UO.InJournal("You are") or UO.InJournal("You lose") or k>200
  UO.DeleteJournal()
 wend
 while (UO.Life<Life) and (uo.SkillVal('Healing',1)<1000)
  CheckLag()
  uo.BandageSelf()
  k=0
  repeat
   Wait(100)
   k=k+1
  until UO.InJournal("You put") or UO.InJournal("barely help") or UO.InJournal("don't need") or k>300
 wend
 UO.FindType('0x0E21','0x0000','backpack')
 if UO.GetQuantity('finditem')<50 Then
  UO.FindType('0x0E20','0x0000','backpack')
  UO.WaitTargetType('0x1008')
  UO.UseObject('finditem')
  MyWait(1000)
 endif
endsub # TrainHealMeditation
##########
sub TrainVeterinary()
 var k, Life, dLife=1
 if uo.Str<=200 then
  repeat
   Eat()
   CheckLag()
   uo.WaitMenu('What do you want to polymorph', 'Daemon')
   uo.Cast('Polymorph')
   MyWait(10000)
   if UO.InJournal('lack') then
    While UO.Mana<UO.INT
     UO.UseSkill('Meditation')
     k=0
     Repeat
      k=k+1
      MyWait(100)
     Until UO.InJournal("You are") or UO.InJournal("You lose") or k>200
     UO.DeleteJournal()
     MyWait(1000)
    Wend
   endif
  until uo.Str>200
 endif
 CheckLag()
 if UO.Waiting() then
  UO.CancelTarget()
 endif
 Life=uo.Str
 uo.UseObject('Curse')
 repeat
  if (UseAnatomy == 1) and (uo.SkillVal('Anatomy',1)<1000) then
   TrainAnatomy()
  endif
  if (UseEvaluatingIntelligence == 1) and (uo.SkillVal('Evaluate Intelligence',1)<1000) then
   TrainEvaluatingIntelligence()
  endif
  if (UO.Timer()-tim2>1200) and (UseSpiritSpeak==1) and (uo.SkillVal('Spirit Speak',1)<1000) then
   TrainSpiritSpeak()
  endif
  if (UseBegging==1) and (uo.SkillVal('Begging',1)<1000) then
   TrainBegging()
  endif
  if (UseTracking==1) and (uo.SkillVal('Tracking',1)<1000) then
   TrainTracking()
  endif
  if (UsePeacemaking == 1) and ((uo.SkillVal('Peacemaking',1)<1000) or (uo.SkillVal('Musicianship',1)<1000)) then
   TrainPeacemaking()
  endif
  if (UseEnticement == 1) and (uo.SkillVal('Enticement',1)<1000) then
   TrainEnticement()
  endif
  if (UseArmsLore == 1) and (uo.SkillVal('Arms Lore',1)<1000) then
   TrainArmsLore()
  endif
  if (UseItemID == 1) and (uo.SkillVal('Item ID',1)<1000) then
   TrainItemID()
  endif
  if (UseTasteID == 1) and (uo.SkillVal('Taste Identification',1)<1000) then
   TrainTasteID()
  endif
  if (UseAnimalLore == 1) and (uo.SkillVal('Animal Lore',1)<1000) then
   TrainAnimalLore()
  endif
  if (UseDetectHidden == 1) and (uo.SkillVal('Detect Hidden',1)<1000) then
   TrainDetectHidden()
  endif
  if (UseSnooping == 1) and (uo.SkillVal('Snooping',1)<1000) then
   TrainSnooping()
  endif
  if (UseStealing == 1) and (uo.SkillVal('Stealing',1)<1000) then
   TrainStealing(StealingMode)
  endif
  MyWait(100)
 until (Life-uo.Life)>=dLife
 CheckLag()
 uo.SetReceivingContainer(uo.GetSerial('backpack'))
 uo.Grab('0','Curse')
 uo.UnSetReceivingContainer(uo.GetSerial('backpack'))
 MyWait(500)
 while (UO.Life<uo.Str) and (uo.SkillVal('Veterinary',1)<1000)
  CheckLag()
  uo.BandageSelf()
  k=0
  repeat
   Wait(100)
   k=k+1
  until UO.InJournal("You put") or UO.InJournal("barely help") or UO.InJournal("don't need") or k>300
 wend
 UO.FindType('0x0E21','0x0000','backpack')
 if UO.GetQuantity('finditem')<50 Then
  UO.FindType('0x0E20','0x0000','backpack')
  UO.WaitTargetType('0x1008')
  UO.UseObject('finditem')
  MyWait(1000)
 endif
endsub # TrainVeterinary
##########
sub TrainBegging()
 if UO.Waiting() then
  UO.CancelTarget()
 endif
 UO.DeleteJournal()
 CheckLag()
 UO.WaitTargetObject("NPC")
 UO.UseSkill('Begging')
 MyWait(3000)
endsub # TrainBegging
##########
sub TrainSnooping()
 var k
 Repeat
  if UO.Waiting() then
   UO.CancelTarget()
  endif
  UO.DeleteJournal()
  CheckLag()
  UO.UseObject('Backpack')
  MyWait(300)
  k=0
  Repeat
   MyWait(100)
   k=k+1
  Until UO.InJournal("You fail") or UO.InJournal("You have lost") or k>30
 Until not UO.InJournal("You fail")
endsub # TrainSnooping
##########
sub TrainStealing(mode)
 var k
 if mode == 1 then
  UO.DeleteJournal()
  CheckLag()
  if StealingItem == 0 then
   uo.FindType('0x0EED',0x0000,'Backpack')
  else
   uo.FindType('0x0F0E',0x0000,'Backpack')
  endif
  MyWait(200)
  if uo.GetQuantity('finditem')>0 then
   uo.UseSkill('Stealing','finditem')
   k=0
   Repeat
    MyWait(500)
    if StealingItem == 0 then
     uo.FindType('0x0EED',0x0000,uo.GetSerial('backpack'))
    else
     uo.FindType('0x0F0E',0x0000,uo.GetSerial('backpack'))
    endif
    k=k+1
   Until UO.InJournal("You fail") or UO.GetQuantity('finditem')>0 or k>7
   MyWait(500)
   if UO.GetQuantity('finditem')>0 then
    uo.DropHere('finditem')
    MyWait(500)
   endif
  else
   if StealingItem == 0 then
    uo.FindType('0x0EED',0x0000,uo.GetSerial('backpack'))
   else
    uo.FindType('0x0F0E',0x0000,uo.GetSerial('backpack'))
   endif
   if UO.GetQuantity('finditem')>0 then
    uo.DropHere('finditem')
    MyWait(500)
   endif
   if UseSnooping == 1 then
    TrainSnooping()
   endif
  endif
 else
  UO.DeleteJournal()
  CheckLag()
  UO.findtype('0x0EED','0x0000','ground')
  MyWait(200)
  if uo.GetQuantity('finditem')>0 then
   UO.Grab('All','finditem')
   MyWait(500)
  endif
  CheckLag()
  UO.findtype('0x0F0E','0x0000','ground')
  MyWait(200)
  if uo.GetQuantity('finditem')>0 then
   UO.Grab('All','finditem')
   MyWait(500)
  endif
 endif
endsub # TrainStealing
##########
sub TrainTracking()
 if UO.Waiting() then
  UO.CancelTarget()
 endif
 UO.DeleteJournal()
 CheckLag()
 uo.WaitMenu('Tracking','Animals')
 UO.UseSkill('Tracking')
 MyWait(1000)
 uo.RClick(50,50)
endsub # TrainBegging
##########
sub TrainDetectHidden()
 var k
 CheckLag()
 if UO.Waiting() then
  UO.CancelTarget()
 endif
 UO.DeleteJournal()
 UO.UseSkill('Detect Hidden')
 MyWait(300)
 k=0
 Repeat
  MyWait(100)
  k=k+1
 Until UO.InJournal("You can see") or UO.InJournal("You see") or k>30
 MyWait(3000)
endsub # TrainDetectHidden
##########
sub TrainAnimalLore()
 var k
 CheckLag()
 if UO.Waiting() then
  UO.CancelTarget()
 endif
 UO.DeleteJournal()
 UO.WaitTargetObject("NPC")
 MyWait(100)
 UO.UseSkill('Animal Lore')
 MyWait(300)
 If UO.InJournal("You can't see the target") Then
  if UO.Waiting() then
   UO.CancelTarget()
  endif
  UO.WaitTargetSelf()
  MyWait(100)
  UO.UseSkill('Animal Lore')
 Endif
 k=0
 Repeat
  MyWait(100)
  k=k+1
 Until UO.InJournal("You can't think") or UO.InJournal("own master") or k>30
 MyWait(3000)
endsub # TrainAnimalLore
##########
sub TrainTasteID()
 var k
 CheckLag()
 if UO.Waiting() then
  UO.CancelTarget()
 endif
 UO.DeleteJournal()
 UO.WaitTargetObject("Food")
 MyWait(100)
 UO.UseSkill('Taste Identification')
 MyWait(300)
 k=0
 Repeat
  MyWait(100)
  k=k+1
 Until UO.InJournal("You cannot discern") or UO.InJournal("It tastes") or k>50
 MyWait(3000)
endsub # TrainTasteID
##########
sub TrainItemID()
 var k
 CheckLag()
 if UO.Waiting() then
  UO.CancelTarget()
 endif
 UO.DeleteJournal()
 UO.WaitTargetObject("Object")
 MyWait(100)
 UO.UseSkill('Item Identification')
 MyWait(300)
 k=0
 Repeat
  MyWait(100)
  k=k+1
 Until UO.InJournal("You can't think") or UO.InJournal("You estimate") or k>50
 MyWait(3000)
endsub # TrainItemID
##########
sub TrainAnatomy()
 var k
 CheckLag()
 if UO.Waiting() then
  UO.CancelTarget()
 endif
 UO.DeleteJournal()
 UO.WaitTargetObject("NPC")
 MyWait(100)
 UO.UseSkill('Anatomy')
 MyWait(300)
 if UO.InJournal("You can't see the target") Then
  if UO.Waiting() then
   UO.CancelTarget()
  endif
  UO.WaitTargetSelf()
  MyWait(100)
  UO.UseSkill('Anatomy')
 endif
 k=0
 Repeat
  MyWait(100)
  k=k+1
 Until UO.InJournal("You can't think") or UO.InJournal("looks") or k>30
 MyWait(3000)
endsub # TrainAnatomy
##########
sub TrainPeacemaking()
 UO.DeleteJournal()
 if UO.Waiting() then
  UO.CancelTarget()
 endif
 CheckLag()
 UO.UseSkill('Peacemaking')
 MyWait(6000)
endsub # TrainPeacemaking
##########
sub TrainEnticement()
 UO.DeleteJournal()
 if UO.Waiting() then
  UO.CancelTarget()
 endif
 CheckLag()
 UO.WaitTargetObject("NPC")
 MyWait(100)
 UO.UseSkill('Enticement')
 MyWait(5000)
endsub # TrainPeacemaking
##########
sub TrainArmsLore()
 var k
 CheckLag()
 if UO.Waiting() then
  UO.CancelTarget()
 endif
 UO.DeleteJournal()
 UO.WaitTargetObject("Object")
 MyWait(100)
 UO.UseSkill('Arms Lore')
 MyWait(300)
 k=0
 Repeat
  MyWait(100)
  k=k+1
 Until UO.InJournal("this item") or UO.InJournal("This item") or k>50
 MyWait(3000)
endsub # TrainArmsLore
##########
sub TrainEvaluatingIntelligence()
 var k
 if UO.Waiting() then
  UO.CancelTarget()
 endif
 UO.DeleteJournal()
 CheckLag()
 UO.WaitTargetObject('NPC')
 UO.UseSkill('Evaluating Intelligence')
 MyWait(300)
 If UO.InJournal("You can't see the target") Then
  if UO.Waiting() then
   UO.CancelTarget()
  endif
  UO.WaitTargetSelf()
  CheckLag()
  UO.UseSkill('Evaluating Intelligence')
 Endif
 k=0
 Repeat
  MyWait(100)
  k=k+1
 Until UO.InJournal("You cannot seem") or UO.InJournal("looks") or UO.InJournal("unsure") or UO.InJournal("perform") or k>60
 MyWait(4000)
endsub # TrainEvaluatingIntelligence
##########
sub TrainSpiritSpeak()
 var k
 if UO.Waiting() then
  UO.CancelTarget()
 endif
 UO.DeleteJournal()
 CheckLag()
 UO.UseSkill('Spirit Speak')
 MyWait(300)
 k=0
 Repeat
  MyWait(100)
  k=k+1
 Until UO.InJournal("You fail") or UO.InJournal("You establish") or k>30
 MyWait(3000)
 tim2=UO.Timer()
endsub # TrainSpiritSpeak
##########
sub CheckLag()
 UO.DeleteJournal()
 UO.Click('backpack')
 Repeat
  Wait(500)
 Until UO.InJournal('backpack')
endsub # CheckLag
##########
sub Eat()
 var ttt, flag
 CheckLag()
 ttt=UO.Timer()
 flag=false
 while not (UO.InJournal("You are stuffed!") or UO.InJournal("to eat any") or UO.InJournal("No item found.") or UO.InJournal("a way to use that") or flag)
  UO.Exec("useobject 'Food'")
  if (UO.Timer()-ttt>150) then
   flag=true
  endif
  Wait(500)
 wend
endsub # Eat
##########
sub MyWait(time)
 var i, i1, count
 if (GuardZone == 1) then
  count = time/100
  i1 = 1
  for i = 1 to count
   if (i-i1)>=10 then
    i1 = i
   endif
   if (UO.life < UO.str) and ((i-i1) == 0) then
    UO.Say("Guards !!!")
   endif
   Wait(100)
  next
 else
  wait(time)
 endif
endsub # MyWait
##########
sub Reconnect()
 var ReconnectTime, rFlag
 ReconnectTime='0'
 rFlag=1
 repeat
  while (uo.ObjAtLayer('Bpack')=='')
   if rFlag then
    ReconnectTime=Time()
    rFlag=0
   endif
   wait(20000)
   uo.Say('')
   wait(3000)
   uo.Say('')
   wait(3000)
   uo.Say('')
   wait(3000)
   uo.LDblClick(357,164)
   uo.LClick(616,459)
   wait(3000)
  wend
  wait(3000)
  if (rFlag==0) and (ReconnectTime<>'0') then
   uo.TextOpen()
   uo.TextPrint(ReconnectTime+' | Потеря связи с сервером, повторное подсоединение')
   rFlag=1
   ReconnectTime='0'
  endif
 until false
endsub # Reconnect
##########
sub Time()
 var hh,mm,ss,hms,t=str(uo.Time())
 if len(t)<=2 then
  hh="0"
  mm="0"
  ss=t
 endif
 if len(t)==3 then
  hh="0"
  mm=left(t,len(t)-2)
  ss=right(t,len(t)-1)
 endif
 if len(t)==4 then
  hh="0"
  mm=left(t,len(t)-2)
  ss=right(t,len(t)-2)
 endif
 if len(t)==5 then
  hh=left(t,len(t)-4)
  hms=left(t,len(t)-2)
  mm=right(hms,len(hms)-1)
  ss=right(t,len(t)-3)
 endif
 if len(t)==6 then
  hh=left(t,len(t)-4)
  hms=left(t,len(t)-2)
  mm=right(hms,len(hms)-2)
  ss=right(t,len(t)-4)
 endif
 return hh+":"+mm+":"+ss
endsub # Time

Mirage · Post by **Mirage** » 2010-11-19 11:47:05

скрипт можно сократить на треть почти.

Code: Select all

UO.DeleteJournal()
CheckLag()
UO.WaitTargetObject("NPC")
UO.UseSkill('Begging')
MyWait(3000)

Вот в такой комбинации НУЖНОЕ для работы скрипта только вот что

Code: Select all

UO.UseSkill('Begging','NPC')
MyWait(3000)

Потом (пробежав глазами) помоему там нет переключалки со скрипта на скрипт по максимальной прокачки.

И данный скрипт подойдет далеко не на всех серверах.
На некоторых скиллы снупинг и бэгинг работают не так как прописано в скрипте, полиморф не работает для прокачки ветеренарии... Так что скрипт хоть и не плохой но можно и получше забахать :roll:

xBRYANx · Post by **xBRYANx** » 2010-11-19 15:30:46

ну ваще...мои скрипты под дрв так как на нем и играю...
полиморф не работает действительно....ща буду сидеть править...и хилинг фигово пашет :oops:

ну а переключалка ,если скилл докачен эт уже буржуям совсем...

xBRYANx · Post by **xBRYANx** » 2010-11-21 19:22:04

скрипт скидывал :GimFlex
и это единственный скрипт который захотел делать не lesser Poison а просто Poison ...
пока рыскал перепробывал кучу...
скрипт работает так:
делает пойзон который может делать самым последним в списке и травит оружие,так по кругу...

Code: Select all

var cont='0x40477AE9'   ;сундук
var ns='0x0F88'
var bottle='0x0F0E'
var colorpoison='0x0998'
var dagger='0x401116E1'      ;что травить будешь

sub main()
uo.cancelmenu()
uo.automenu('What sort of potion do you want to','(last)')
uo.useobject(cont)
wait(500)
while not uo.dead()
checkns()
checkbottles()
alchemypoison()
poisondagger()
wend
endsub

Sub checkns()
uo.findtype(ns,'-1','backpack')
if uo.getquantity('finditem')<=10 then
uo.findtype(ns,'-1',cont)
if uo.findcount() then
  uo.moveitem('finditem','100','backpack')
  wait(500)
endif
endif
endsub

Sub checkbottles()
uo.findtype(bottle,'0x0000','backpack')
if uo.getquantity('finditem')<=10 then
uo.findtype(bottle,'-1',cont)
if uo.findcount() then
  uo.moveitem('finditem','100','backpack')
  wait(500)
endif
endif
endsub

Sub alchemypoison()
uo.deletejournal()
uo.usetype(ns)
repeat
Wait(50)
until UO.InJournal("You put the") OR UO.InJournal("You toss the failed")
endsub

Sub poisondagger()
UO.FindType(bottle,colorpoison,'backpack')
if uo.findcount() then
uo.deletejournal()
uo.waittargetobject(dagger,'finditem')
uo.useskill('Poisoning')
repeat
  wait(50)
until UO.InJournal("You fail to apply") OR UO.InJournal("You apply the poison")
endif
endsub

xBRYANx · Post by **xBRYANx** » 2010-11-21 21:50:21

поправил самый обычный тинкеринг...чтоб делать банки..потому как была ошибка...
правка ваще милиметорная просто...
и еще не понятный у меня глюк с ним:до того как врубить скрипт нада открыть и закрыть сундук из которого будешь вытаскивать инги...
но сразу не увидешь в чем беда была:

Code: Select all

; TinkerLockPick. v.1.00b © Edred
sub tinker()
   VAR Sunduk = '0x4025C3DE'     ;Сундук
   VAR Ingi = '0x1BEF'   
   VAR Instrum = '0x1EBC'  
   VAR Bottle = '0x0F0E '        
   VAR Kolvo = 200         
   VAR k = 0
   UO.UseObject(Sunduk)
   wait( 500 )
   While TRUE
      UO.FindType( Ingi, -1, Sunduk )   ; Ищем инги в сундуке
      If UO.FindCount() == 0 Then
         UO.Print("Iron Ingots not found, script terminated")
         return
      Endif
      UO.Grab( Str( Kolvo ), 'finditem' )
      wait( 2000 )
      While UO.Count( Ingi ) > 2
         ; Пока в паке есть инги
         UO.Print('Ostalos ' + Str( UO.Count( Ingi ) ) + ' ingots' )
         UO.DeleteJournal()
          UO.CancelMenu()
                  UO.UseType( Instrum )
         UO.WaitMenu ('Tinkering', 'Tools', 'Tools', 'empty bottle' )
        
                 k = 0
         while NOT UO.InJournal('You put') AND NOT UO.InJournal('fail') AND ( k < 30 )
            k = k + 1
            wait(500)
         wend
         if UO.Count( Bottle ) > 0 then
            UO.FindType( Bottle, -1, -1 )
            UO.MoveItem( 'finditem', 0, Sunduk )
            wait( 1000 )
            UO.Print( 'Bottle moved' )
         end if
      Wend
   Wend
end sub

Mirage · Post by **Mirage** » 2010-11-21 22:26:50

Code: Select all

   VAR k = 0
   UO.UseObject(Sunduk)
   wait( 500 )
 While TRUE

добавь

Для сравнения:

Code: Select all

VAR Container   = '0x40B5267F'   ;айрон, рыба, инструменты, может быть равен Sunduk 1
VAR Sunduk1   = '0x40B5267F'      ;пустые мешки
VAR Sunduk2   = '0x40B52599'      ;полные
VAR Instrum   = '0x1EBC'      ;набор жестянщика
VAR hammer   = '0x13E3'      ;кузнечный молоток
VAR saw      = '0x1034'      ;пила
VAR Ing      = '0x1BEF'      
VAR log      = '0x1BDD'   
VAR key      = '0x1010'      
VAR Lock   = '0x14FB'      
VAR Bottle   = '0x0F0E'      
VAR Dagger   = '0x0F51'      
VAR club   = '0x13B3'      
VAR Bow      = '0x13B1'      #лук#
VAR spool   = '0x0FA0'      #нитки#
VAR Сap      = '0x171C'      #колпак#
VAR cloth   = '0x175D'      #ткань#
VAR Skit   = '0x0F9D'      #швейный набор#
VAR Deed    = '0x14EF'
VAR Meshok    = '0x0E76'      ;тип мешка
var havka   = '0x097B'
VAR MeshSer, d, LastTimer, timemove, itemM
var quantity = 150; количество предметов в 1 мешке
var msg ='You put|положили|fail|не удалось|You broke|сломали'
var printcolour = '1069'
VAR HIDE = 1; если 1 прячемся, если 0 нет.
###################
sub TinkerBottle()
   var menu = "waitmenu 'Tinkering' 'Tools' 'Tools' 'Empty bottle'" 
   var item = Bottle
      UO.UseObject(Container)
      wait( 500 )
      UO.UseObject(Sunduk1)
      wait( 500 )
      UO.UseObject(Sunduk2)
      wait( 500 )
   WHILE NOT UO.Dead()
      GET(ing, Container, 10, 100) 
      GET(Instrum, Container, 2, 2) 
      if HIDE then
         Hide()
      endif
      UO.DeleteJournal()
      LastTimer=UO.Timer()
      Repeat
         UO.DeleteJournal()
         LastTimer=UO.Timer()
         UO.exec( menu )
         UO.Usetype( Instrum )
         repeat
            wait( 100 )
         until UO.InJournal( msg ) or UO.Timer()>LastTimer+150
      Until UO.Count( item ) > 0
      checklag()
      PUT(item, Container) 
      UO.FindType( item, -1, Container)
      uo.charprint(printcolour,'Банок в банке: '+Str(UO.GetQuantity('finditem')))
   WEND
end sub
Sub eat()
   GET(havka, Container, 1, 20) 
   REPEAT
      UO.DeleteJournal()
      LastTimer=UO.Timer()
      UO.findtype(havka,-1,'backpack')
      If UO.FindCount() > 0 Then
         UO.Useobject('finditem')
         wait(200)
      Else
         uo.charprint(printcolour, 'кончилась рыба' )
         return 0
      end if
   Until UO.InJournal("simply too full to eat|stuffed!|think|found|Вы ничего не можете") OR UO.Timer()>LastTimer+200
   PUT(havka, Container)
end sub
Sub GET(item, cont, min, max) ; предмет, откуда, минимум, сколько брать 
   If UO.Count( item ) < min Then
      UO.FindType( item, '-1', cont )
      if UO.FindCount() > 0 Then
         uo.charprint(printcolour,'Сырья в сундуке: '+Str(UO.GetQuantity('finditem')) )  

                itemM=UO.GetSerial('finditem')
                timemove=UO.Timer()
                while UO.ContainerOf(itemM)==cont && timemove+20>UO.Timer() 
            uo.moveitem('finditem', max, 'backpack')
                    wait(300)
                wend
      else
         uo.charprint(printcolour, 'Полностью кончилось сырье' )
         UO.CancelMenu()
         MyTerminate()
      endif
   Endif
end sub
Sub PUT(item, cont)
   while UO.Count( item ) > 0
      UO.FindType( item, -1, -1 )
                itemM=UO.GetSerial('finditem')
                timemove=UO.Timer()
            UO.MoveItem( 'finditem', 0, cont )
                while UO.ContainerOf(itemM)=='my' && timemove+20>UO.Timer()
                    wait(300)
                wend
   wend
end sub
Sub Hide()
   VAR LastTimer, n=0, HidFlag=1
   if UO.Hidden() then
      HidFlag=0
   else
   end if
   while HidFlag
      DeleteJournal("can't seem to hide|to perform|stop trying|прекратили|не удалось|удачно|You have hidden yourself well")
      LastTimer=UO.Timer()
      UO.WarMode(0)
      UO.UseSkill('Hiding')
      repeat
         wait(50)
      until UO.InJournal("can't seem to hide|to perform|stop trying|прекратили|не удалось|удачно|You have hidden yourself well") || LastTimer+50<UO.Timer()
      if UO.InJournal("0xA5F8|удачно|You have hidden yourself well") then
         HidFlag=0
      else
         n=n+1
         if n>3 then
            UO.Set('quiet','0')
            uo.charprint(printcolour,'Спрятаться не получается, происходит что-то тревожное и непонятное, готовься к смерти, неудачнег!')
            UO.Set('quiet','1')
            MyTerminate()
         end if
      end if
   wend
end sub
Sub DeleteJournal(msg)
   While UO.InJournal(msg)
      UO.SetJournalLine(UO.InJournal(msg) - 1,'') 
   wend
endsub
Sub MyTerminate()
   UO.Set('quiet','1')
   UO.CancelMenu()
   UO.IgnoreReset()
   UO.Set('quiet','0')
   UO.Exec('terminate all')
end sub
Sub checklag()
   DeleteJournal("ackpack")
   UO.Click("backpack")
   repeat
      wait(100)
   until UO.InJournal("ackpack")
end sub

xBRYANx · Post by **xBRYANx** » 2010-11-21 22:39:12

ок поправил...ппц выложил чужие скрипты дык еще и закасячил =)

xBRYANx · Post by **xBRYANx** » 2010-11-28 22:35:09

потом кину переделаную ковку брони

xBRYANx · Post by **xBRYANx** » 2010-12-05 04:28:16

скрипт на смену оружия и лука...
немного добавил для нормального пвп...

работает так:
врубаете SelectWeps и тыкаете на оружие какое будет менять..когда выбрали
можете спокойно пользоваться скриптом ArmWeap
скрипт пока что тестируеться на все баги....

Code: Select all

sub SelectWeps()  ; выбор оружия
UO.Exec('addobject Shield')
    While UO.Targeting()
       Wait(100)
    Wend
UO.Exec('addobject Weapon')
    While UO.Targeting()
       Wait(100)
    Wend
UO.Exec('addobject Bow')
    While UO.Targeting()
       Wait(100)
    Wend
endsub

sub ArmWeap()  ; поочередное одевание лука / щита+дива.
  If UO.GetGlobal( 'mywep' ) == 'bow' Then
    UO.SetGlobal( 'mywep', 'shield' )
    UO.UseObject( 'Shield' )
    UO.UseObject( 'Weapon' )
    uo.waittargetlast()
  Else
    UO.SetGlobal( 'mywep', 'bow' )
    UO.UseObject( 'Bow' )
    uo.attack('lastattack')
  Endif
endsub

Yoko

буду сюда переделанные чужие....

буду сюда переделанные чужие....

Re: буду сюда переделанные чужие....

Re: буду сюда переделанные чужие....

Re: буду сюда переделанные чужие....

Re: буду сюда переделанные чужие....

Re: буду сюда переделанные чужие....

Re: буду сюда переделанные чужие....

Re: буду сюда переделанные чужие....

Re: буду сюда переделанные чужие....

Re: буду сюда переделанные чужие....

Re: буду сюда переделанные чужие....

Re: буду сюда переделанные чужие....

Re: буду сюда переделанные чужие....

Re: буду сюда переделанные чужие....

Re: буду сюда переделанные чужие....

Re: буду сюда переделанные чужие....

Re: буду сюда переделанные чужие....