догонялка

AID · Post by **AID** » 2006-03-24 00:44:21

чтобы чар бегал за другим не отрываясь и бил как будто они стоят в упор , люди добрые помогите нубу стать папи)))

Зарание спасибо

Grin · Post by **Grin** » 2006-03-24 10:56:20

на сфере играешь?
Ставишь себе прив 4
потом follow на жертву;)

Edred · Post by **Edred** » 2006-03-24 11:34:57

Одному нужна убегалка, другому догонялка...

Destruction · Post by **Destruction** » 2006-03-24 22:56:04

Не, ну название - весёлое.

Запомните, Injection - для читерства можно использовать, но много не начитишь, не выдет у тебя на мопеде носиться за человек на выделенке как угорелый без PRIV=4, и тем более бить без остановок - это делается только ручками.

Самый быстрый бег - ходилка (c) Beyonder и alt+lclick, от обоих можно убежать грамотно юзая макросы.

Edred · Post by **Edred** » 2006-03-25 01:19:02

Destruction wrote:Самый быстрый бег - ходилка (c) Beyonder

Хе-хе, наивный...

SLAK · Post by **SLAK** » 2006-03-25 10:38:39

Edred wrote:
Destruction wrote:Самый быстрый бег - ходилка (c) Beyonder
Хе-хе, наивный...

Хе-хе, поподробней изложи мыслю... Ну там скриптец скинь или ссылку

flake · Post by **flake** » 2006-03-25 10:55:50

Загляни в топик со скриптами Едреда.

SLAK · Post by **SLAK** » 2006-03-25 13:44:50

flake wrote:Загляни в топик со скриптами Едреда.

Эт та что:
Autor - Sergious, Edited - Edred.

Первый раз ещё на первой странице встречается (кажись в автолоаде), ещё ходилка через изю , ещё какаято простенькая ходилочка под скрипт сбора навоза(явно не о ней Едред упомянул)...

Edred · Post by **Edred** » 2006-03-25 16:47:13

Эффективную ходилку средствами одного инжекта реализовать пока невозможно. Ни на одной из существующих ходилок чар не может при включенном "Always run" верхом на лошади продираться через густой лес, не задумываясь перед каждым деревом или кустом на пути.

В то же время существует масса именно настолько эффективных ходилок (точнее бегалок) под ИзиУО, всех любопытствующих отсылаю на форум Изи, которые элементарно синхронизируются в работе с скриптами инжекта. Как делается последнее - смотри мой скрипт на бот беггинга в теме с моим наследством. И кстати, рекомендую всем сомневающимся взять и запустить тот тривиальный скриптик, который я там привожу (на хождение). И сделайте это в городе каком-нибудь, и введите координаты другого конца города, сидите на лошади и включите бег. И посмотрите на результат.

А хотите более эффективную бегалку под изи? Вот тоже одна из самых простых (но посложнее):

Code: Select all

;================================== 
; Script Name: RKSpotAutoWalker.txt
; Author: Roadkill
; Version: 1.1 
; Client Tested with: 4.0.3d
; EUO version tested with: build 0093
; Shard OSI / FS: OSI
; Revision Date: 15Jul04
; Public Release: 10Jul04
; Global Variables Used: none
; Purpose: Auto or manual long-distance pathfinding to a spot with continuous 
; 	distance & direction-arrow.  If auto enabled (3rd param #true) it 
;	AUTO-PATHFINDS no matter how far the spot is!  Autosenses if called
;	or standalone andadjusts. Auto-unblocks. Auto-adjusts for hills.
;==================================
;Instructions: Can be run standalone or "called", it autosenses.  If called, use:
;example: call RKSpotAutoWalker.txt xcoord ycoord <#true/#false, autowalk?> <use menu?T/F>
;--where xcoord/ycoord are where you want to go, 3rd param enables autowalk if #true
;  or if #false just gives continuous direction and distance and you manually walk there.
;  The 4th param #true/#false is whether to use the menu, #true uses it. This is for
;  those using this CALLED as a plugin who have their own menu.
set %mapxcoord %1
set %mapycoord %2
set %autoSpotWalk %3
set %useSAWmenu %4
set %SWexitCmd exit
set %symbols щьшюъэчыN
set !zfix 15
if %0 = 0 || %0 = n/a
{
	initevents
	set %autoSpotWalk #true
	set %mapxcoord #charposx
	set %mapycoord #charposy
	set %SWexitCmd halt
	set %useSAWmenu #true
	gosub SAWmenu
	display ok Demo-Mode. This is your spot, we'll pathfind back here.$
	+ Now run like hell off somewhere and then hit PLAY
	pause
}
set %autoWalkMsg go-auto
if %autoSpotWalk
	set %autoWalkMsg go-manual
if %useSAWmenu
	gosub SAWmenu
	set !ptime #scnt + 3
	set !oldx #charposx
	set !oldy #charposy
	set !pathfindFailures 0
	gosub AlwaysRun
sawloop:
	if #menubutton = ToggleAutoWalk
		gosub ToggleAutoWalk
	gosub DistToSpot %mapxcoord %mapycoord dist
	gosub FindThingsDir %mapxcoord %mapycoord spotdir
	set !picksymbol %spotdir + 1
	str mid %symbols !picksymbol 1
	menu set textdist %dist
	menu set textsymbol #strres
	if %dist = 0
	{
		wait 10
		%SWexitCmd
	}
	if ! %autoSpotWalk
		goto sawloop
	if #charposx = !oldx && #charposy = !oldy && #scnt > !ptime
		gosub unblock %spotdir
	if #scnt > !ptime
	{
		set !ptime #scnt + 3
		set !oldx #charposx
		set !oldy #charposy
	}
	gosub GetPathFindingWaypoint %mapxcoord %mapycoord 5 waypointx waypointy
	deletejournal
	event pathfind %waypointx %waypointy #charposz
	wait 5
	scanjournal 1
	if get_there in #journal
	{
		set !pathfindFailures !pathfindFailures + 1
		set !zfix !zfix * -1
		set !waypointz #charposz + !zfix
		;double the vertical offset after 3 pathfind failures
		if !pathfindFailures > 3 3
			set !waypointz !waypointz + !zfix
			event sysmessage adjusting zfix
			wait 10
		deletejournal
		event pathfind %waypointx %waypointy !waypointz
		wait 5
		scanjournal 1
	}
	if pathfinding in #journal
		set !pathfindFailures 0
goto sawloop
;==============
sub SAWmenu
	menu Clear
	menu Window Size 100 100
	menu Font Name Wingdings
	menu Font Size 30
	menu Font Style b
	menu Font Color red
	menu Font Transparent #false
	menu Font Align Left
	menu Text textsymbol 0 0 -
	menu font size 10
	menu  font name ariel
	menu text text1 0 70 distance:
	menu text textdist 0 85 %dist
	menu button ToggleAutoWalk 0 55 85 15 %autoWalkMsg
	menu show
return
;===========
SUB FindThingsDir
;ver 1.2 10Jul04 by Roadkill
;purpose: find the direction from you that a thing is
;%1= #findx of object, it's UO world coord
;%2=#findy of object, it's UO world coord
;%3= the name of the return var, i.e. 'dir', 'thingsdirection' by default
;%3 holds its dir from you 0-nw 1-n 2-ne 3-e 4-se 5-s 6-sw 7-w 8-sametile
;* @example call rksubs.txt FindThingsDir %mapxcoord %mapycoord spotdir
	SET !itsX %1
	SET !itsY %2
	if %0 < 3
		set %3 thingsdirection
	IF !itsX = #charposx && !itsY < #charposy
		SET % . %3 1 ;N
	IF !itsX > #charposx && !itsY < #charposy
		SET % . %3 2 ;NE
	IF !itsX > #charposx && !itsY = #charposy
		SET % . %3 3 ;E
	IF !itsX > #charposx && !itsY > #charposy
		SET % . %3 4 ;SE
	IF !itsX = #charposx && !itsY > #charposy
		SET % . %3 5 ;S
	IF !itsX < #charposx && !itsY > #charposy
		SET % . %3 6 ;SW
	IF !itsX < #charposx && !itsY = #charposy
		SET % . %3 7 ;W
	IF !itsX < #charposx && !itsY < #charposy
		SET % . %3 0 ;NW
	IF !itsX = #charposx && !itsY = #charposy
		SET % . %3 8 ;same tile
RETURN
;=========================
;**
;* @name DistToSpot
;* @author Roadkill
;* @ver 1.0 10Jul04 
;* @purpose find the distance between you and a spot
;* @params %1= spot xcoord, required
;*	%2= spot ycoord, required
;*	@%3= the var to return the distance in
;* @returns: @%3 holds distance
;* @example call rksubs.txt DistToSpot %mapxcoord %mapycoord dist
;* @status
Sub DistToSpot
	set !_xDist ( #charposx - %1 ) abs
	set !_yDist ( #charposy - %2 ) abs
	set % . %3 !_ydist
	if !_xdist > !_ydist
		set % . %3 !_xdist
return
;===========================
;**
;* @name GetPathFindingWaypoint
;* @author Roadkill
;* @ver 1.0 10Jul04 
;* @purpose picks a "waypoint" some distance towards a final spot you're working to.
;*	if incremental distance > 11, 11 is used, if dist <= 11 the spot itself returned
;* @params %1= spot xcoord, required
;*	%2= spot ycoord, required
;*	%3 = the distance from you to pick the waypoint, 11 is max
;*	@%4= the var to return waypoint x coord
;*	@%5= the var to return waypoint y coord
;* @returns: @%4 and %5
;* @example call rksubs.txt GetPathFindingWaypoint %mapxcoord %mapycoord 5 waypointx waypointy
;* @status
sub GetPathFindingWaypoint
	if %3 > 11
		set %3 11
	if abs ( #charposx - %1 ) <= 11 && abs ( #charposy - %2 ) <= 11
	{
		set % . %4 %1
		set % . %5 %2
		return
	}
	set % . %4 #charposx - %3
	if #charposx < %1
		set % . %4 #charposx + %3
	if #charposx = %1
		set % . %4 #charposx		
	set % . %5 #charposy - %3
	if #charposy < %2
		set % . %5 #charposy + %3
	if #charposy = %2
		set % . %5 #charposy
return
;==========
sub Unblock
;%1 is %spotdir
event sysmessage unblocking!
wait 10
	set !revdir %1 - 4
	if %1 < 4
		set !revdir %1 + 4
	event macro 5 !revdir
	wait 1
	event macro 5 !revdir
	if !revdir >= 2
		set !revdir !revdir - 2
	else 
		set !revdir !revdir + 2
	event macro 5 !revdir
	wait 1
	event macro 5 !revdir
return
;=========
SUB AlwaysRun
;purpose: ensure that always run is toggled on
	EVENT MACRO 32 0
	WAIT 2
	IF now_on IN #SYSMSG
		RETURN
	EVENT MACRO 32 0
RETURN
;===========
sub ToggleAutoWalk
;changes %autospotwalk and %autowalkmsg, assumes they are global
	set #menubutton n/a
	if %autoSpotWalk
	{
		set %autoSpotWalk #false
		set %autoWalkMsg go-auto
	}
	else
	{
		set %autoSpotWalk #true
		set %autoWalkMsg go-manual
	
	}
	menu set ToggleAutoWalk %autoWalkMsg
return
;======end of RKSpotAutoWalker.txt============
;ver 1.1 added go-auto/manual button

Согласование с инжектом в эту ходилку не вставлено, но это делается элементарно.

SLAK · Post by **SLAK** » 2006-03-25 17:31:59

Хе-хе...
Если б я ещё хоть чтото понимал в изе

Зы: 6 строка рабочего кода, это она так и выгядит?

Code: Select all

set %symbols щьшюъэчыN

Edred · Post by **Edred** » 2006-03-25 21:51:35

SLAK wrote:Хе-хе...
Если б я ещё хоть чтото понимал в изе
Зы: 6 строка рабочего кода, это она так и выгядит?
Code: Select all
set %symbols щьшюъэчыN

Хз, именно так и выглядит. Я этот скрипт по косточкам не разбирал, помню что с год назад содрал его с сайта Изи, протестил, результат мне понравился, я решил на основе него себе какую-то новую ходилку сделать (кажись как раз убегалку в мининг), но так времени и не нашлось.

А по поводу первого - язык в Изе еще проще чем в инжекте...

SLAK · Post by **SLAK** » 2006-03-25 22:44:53

Edred wrote: А по поводу первого - язык в Изе еще проще чем в инжекте...

Мои знания в скриптинге основываются на уроках + почти год практики... А на изю я уроков не видел, только ФАКи по командам...
Нащёт скрипта... Я его запускаю и сходу там ошибки полезли , что переменные не казал, мож привести пример как его запустить? Спростой ходилкой с твоего наследства легко получилось , без мороки, но её качаство меня не устроило, ходилка Бейондера мож и медленнее зато нужные мне припятствия обходит

Edred · Post by **Edred** » 2006-03-25 22:54:58

В комментариях скрипта все же написано "русским" языком:

;Instructions: Can be run standalone or "called", it autosenses. If called, use:
;example: call RKSpotAutoWalker.txt xcoord ycoord <#true/#false, autowalk?> <use menu?T/F>
;--where xcoord/ycoord are where you want to go, 3rd param enables autowalk if #true
; or if #false just gives continuous direction and distance and you manually walk there.
; The 4th param #true/#false is whether to use the menu, #true uses it. This is for
; those using this CALLED as a plugin who have their own menu.

То бишь, запускать можно напрямую или через call (в изе вызов других скриптов идет через эту команду, в мою изевую ходилку вместо команды move вставь строку:

Code: Select all

call RKSpotAutoWalker.txt xcoord ycoord <#true/#false, autowalk?> <use menu?T/F>

естественно подставив параметры, первые два - координаты, дальше тебе нужно #true, последний параметр #false если ты не подключил изевую библиотеку для создания менюшек. Изю надо естественно взять свежую. Параметры передавать в изевый скрипт из инжекта через глобальные переменные Изи.

Edred · Post by **Edred** » 2006-03-25 23:00:22

В общем, в изе тебе надо запустить такой скрипт:

Code: Select all

; Процедура перемещения чара для скриптов инжекта
; Считывает все параметры из регистри
;
; v.1.03 (c) Edred, переделка под RKSpotAutoWalker
;

initevents 
set *1 0
set *2 0

loop:
if *1 <> 0
{
	wait 2
	call RKSpotAutoWalker.txt *1 *2 #true #false
	set *1 0
}
goto loop

Ну и естественно не забыть положить файл RKSpotAutoWalker.txt в папку изи

Вызов же из инжекта также как и в моем скрипте на беггинг. Только последние два параметра уже на фиг не нужны.

SLAK · Post by **SLAK** » 2006-03-26 11:30:39

[quote="Edred"][/quote]
Пасиб Батька заработало

Качество не плохое... но тут возникает вопрос, как с инжи оборвать выполнение хождения? А то пока скриптец добежит до цели она умудряется пару раз локацию сменить

Тоесть у цели есть начальные координаты Х и У, пока я на полпути к цели, цель меняет кординаты на Х+5, У... Как мне не бежа в Х и У, сразу бежать в Х+5, У ? В инжекте я отслежу изменение координат, а как заставить Изю остановиться?

Edred · Post by **Edred** » 2006-03-26 19:04:29

Дык возьми не этот скрипт, а подбери себе с форума изи другой, который на "догонялку". Там же их полно. Этот хорош для движения к статичной цели.

Кроме того, в изе можно без проблем отслеживать передвижение твоей цели.

SLAK · Post by **SLAK** » 2006-03-26 20:23:05

[quote="Edred"][/quote]
Эх придётся лезть на форум изи

Пасиб за помощь и советы.

Edred · Post by **Edred** » 2006-03-27 00:26:49

Это что, трагедия такая? Вообще-то тебе надо зайти сюда:
http://www.easyuo.com/psl.php?cat=122
и выбрать себе по вкусу скриптик...

ЗЫ: Ну и еще тут проверить:
http://www.easyuo.com/psl.php?cat=102

ЗЗЫ: Тут тоже может быть:
http://www.easyuo.com/psl.php?cat=129

ЗЗЗЫ: Тут врядли, но зато какие прикольные скрипты, инжект отдыхает:
http://www.easyuo.com/psl.php?cat=133

ЗЗЗЗЫ: Ну и конечно этот раздел пропустить нельзя:
http://www.easyuo.com/psl.php?cat=91
Тут масса интересного, некоторое выглядит очень захватывающе, например:

Code: Select all

Auto-fighting/killing of victims. Auto Defends if attacked. Can be run as plugin or standalone. Many tactics choices, including various magery, necro, all melee skills, peace combos, pets, pets with peace, pets with magery, etc. Script also works with Roadkill's HealthWatch to keep you healed while it fights.

Наслаждайся. Вообще, с моей точки зрения (и не только моей, насколько мне помнится, и Йоко ее придерживается), связка Инжект и Изи - очень сильная штучка. Гораздо сильнее каждого компонента по отдельности или любых других комбинаций скриптовых утилит.

SLAK · Post by **SLAK** » 2006-03-27 10:20:54

Edred wrote: Изи - очень сильная штучка. Гораздо сильнее каждого компонента по отдельности или любых других комбинаций скриптовых утилит.

Когда увидел, что ты отписался в топе , думал просто написал "Незашто" или "приятно когда благодарят"... А когда открыл у меня глаза на лоб полезли. Батька ты помешанный

Но за твою помешанность тебе огромнейший респект, а то я на форуме лиш плагиат нашёл

Edred · Post by **Edred** » 2006-03-27 20:48:23

Да я на сайт и форум Изи раза два в неделю заглядываю... Нравится мне эта прога.