!прокачка боевых 2 чарами!

[ghost_hnt]

будьте добры заделиться скриптиком на прокачку сразу двух чаров (боевых скилов)!
чтобы фигарили друг друга а потом хелили, если можно на свордманшип или на мейсфайтинг

ЗАРАНЕЕ БЛАГОДАРЕН

[Dron D.]

Такой срипт точно есть, называется Sparring или sparing как то так, в поиске смотри. В автолоуде саваджа вроде был.

[Savage]

Описалово тут: https://yoko.uokit.com/viewtopic.php?p= ... d423b#2026

Code: Select all

sub sreset()
	UO.SetEasyUO(80,"1")
	UO.SetEasyUO(90,"1")
end sub


sub sparring()
	VAR Char1='0x0003638F'
	VAR Char2='0x000311AA'
	VAR Enemy, ESelf, EEnemy
	VAR Weapon, Shield, WpnType, ShldType
	VAR TazikType='0x1008',BloodBndg='0x0E20'
	VAR MinLife=40
	

	if UO.GetSerial('self')==Char1 then
		Enemy=Char2
		EEnemy=90
		ESelf=80
	else
		Enemy=Char1
		EEnemy=80
		ESelf=90
	endif

	Weapon=UO.ObjAtLayer('Rhand')
	If Weapon<>"" Then
		WpnType=UO.GetGraphic(Weapon)
	Endif

	Shield=UO.ObjAtLayer('Lhand')
	If Shield<>"" Then
		ShldType=UO.GetGraphic(Shield)
	Endif
	
	UO.SetEasyUO(ESelf,"0")

	while NOT UO.Dead()
	
		repeat
			wait(500)
		until UO.GetEasyUO(ESelf)=="0" AND UO.GetEasyUO(EEnemy)=="0" 
		
		UO.Exec("warmode 1")
		UO.Attack(Enemy)
		
		while UO.Life>=MinLife AND UO.GetEasyUO(EEnemy)=="0" 
			wait(100)
		wend

		UO.SetEasyUO(ESelf,"1")
		UO.Exec("warmode 0")
		wait(1000)
		UO.Exec("warmode 0")

		If UO.Count('0x0E21')<20 Then
			UO.FindType('0x0E20','0x0000','backpack')
			UO.WaitTargetType(TazikType)
			UO.UseObject('finditem')
			wait(1000)
		Endif

		while UO.Life<UO.Str
			UO.DeleteJournal()
			UO.BandageSelf()
			Repeat
				wait(500)
			Until UO.InJournal('Âàì') OR UO.InJournal('Âû ïî') OR UO.InJournal('Âàøà')
			wait(5000)
		wend

		If Shield<>"" Then
			UO.Equipt('Lhand',ShldType)
			wait(2000)
		Endif

		If Weapon<>"" Then
			UO.Equipt('Rhand',WpnType)
			wait(2000)
		Endif
		
;		UO.UseSkill('Spirit Speak')
;		wait(3000)
		UO.SetEasyUO(ESelf,"0")
	wend
end sub

Арчери:

Code: Select all

sub sreset()
	UO.SetEasyUO(80,"1")
	UO.SetEasyUO(90,"1")
end sub


sub Archery()
	VAR Char1='0x000CF3A5'
	VAR Char2='0x000BF49A'
	VAR Enemy, ESelf, EEnemy
	VAR Weapon, Shield, WpnType, ShldType
	VAR TazikType='0x1008',BloodBndg='0x0E20'
	VAR MinLife=60
	

	if UO.GetSerial('self')==Char1 then
		Enemy=Char2
		EEnemy=90
		ESelf=80
	else
		Enemy=Char1
		EEnemy=80
		ESelf=90
	endif

	Weapon=UO.ObjAtLayer('Lhand')
	If Weapon<>"" Then
		WpnType=UO.GetGraphic(Weapon)
	Endif
UO.Print(Weapon)

	UO.SetEasyUO(ESelf,"0")

	while NOT UO.Dead()
	
		repeat
			wait(500)
		until UO.GetEasyUO(ESelf)=="0" AND UO.GetEasyUO(EEnemy)=="0" 
		
		UO.Exec("warmode 1")
		UO.Attack(Enemy)
		
		while UO.Life>=MinLife AND UO.GetEasyUO(EEnemy)=="0" 
			wait(100)
		wend

		UO.SetEasyUO(ESelf,"1")
		UO.Exec("warmode 0")
		wait(1000)
		UO.Exec("warmode 0")

		UO.FindType('0x0E21','0x0000','backpack')
		If UO.GetQuantity('finditem')<20 Then
			UO.FindType('0x0E20','0x0000','backpack')
			UO.WaitTargetType(TazikType)
			UO.UseObject('finditem')
			wait(1000)
		Endif

		while UO.Life<UO.Str
			UO.DeleteJournal()
			UO.BandageSelf()
			Repeat
				wait(500)
			Until UO.InJournal('put') OR UO.InJournal('help') OR UO.InJournal('cure')
		wend

		If Weapon<>"" Then
			UO.Equipt('Lhand',WpnType)
			wait(2000)
		Endif
		
		UO.UseSkill('Spirit Speak')
		wait(3000)
		UO.SetEasyUO(ESelf,"0")
		
		UO.WaitTargetGround('0x0F3F')
		UO.Grab('all')
	wend
end sub

[ghost_hnt]

спасибки!
!Великий скриПТ! (если рабочий еще)