mining + spirit

[_ALF_]

Возможно ли загнать прокачку спирит спик в миниг? ну чтоб копал и и одновременно спирит качал ?

[Edred]

А почему нет? У меня так сделано - так как не вкачан только спирит спик фактически. Поэтому засовываю его везде где только можно.

На этом форуме полно моих скриптов, в которых есть специальная функция и блок ее вызова раз в 5 минут. Засунь в свой мининг и не мучайся.

[_ALF_]

в которых есть специальная функция и блок ее вызова раз в 5 минут. Засунь в свой мининг и не мучайся.

Edred ты не мог бы выложить в этот тот эту функцю или ссылку кинуть где посмотреть мона

[Edred]

В начало скрипта ставишь:

Code: Select all

VAR SpiritTime = UO.Timer()

Там где хошь запускать прокачку ставишь:

Code: Select all

If ( UO.Timer() - SpiritTime ) / 600 > 5 Then
   ; Прошло 5 минут с момента последней прокачки Spirit Speak
   SpSpeak()
   SpiritTime = UO.Timer()
Endif

В конец скрипта добавляешь функцию (не забудь проверить, такие ли у тебя на шарде мессаги):

Code: Select all

#####################################################################
; Spirit Speak v.1.00b (c) Edred
;
; Разовая прокачка спирит спика. Предназначена для вызова из других скриптов.
;
sub SpSpeak()
   VAR mod = UO.WarMode(), num
   VAR fizzle = 'You fail your attempt'
   VAR success = 'You establish a connection'
   UO.WarMode( 0 )
   DeleteJournal( success )
   repeat
      DeleteJournal( fizzle )
      UO.UseSkill( 'Spirit Speak' )
      num = 1
      repeat
         wait(100)
         num = num + 1
      until UO.InJournal( fizzle ) OR UO.InJournal( success ) OR num > 600
   until UO.InJournal( success )
   UO.WarMode( mod )
endsub

#####################################################################
Sub DeleteJournal( string1 )
   VAR nom = UO.InJournal( string1 )
   If nom > 0 Then
      UO.SetJournalLine( Nom - 1, 'string replaced' )
      DeleteJournal( string1 )
   Endif
endsub